Question

FSO生成ASP静态页面

FSO怎么生成ASP静态页面，怎么把动态页面弄成静态的啊？
输出的HTML页面在哪里啊

Answer 1

Server.ScriptTimeOut=50000
Function getHTTPPage(Path)
t = GetBody(Path)
getHTTPPage=BytesToBstr(t,"GB2312")
End function

Function GetBody(strUrl)
dim objXmlHttp
set objXmlHttp = Server.CreateObject("Microsoft.XMLHTTP")
objXmlHttp.open "GET",strUrl,false
objXmlHttp.send()
GetBody= objXmlHttp.responseBody
set objXmlHttp=nothing
End Function

Function BytesToBstr(body,Cset)
dim objstream
set objstream = Server.CreateObject("adodb.stream")
objstream.Type = 1
objstream.Mode =3
objstream.Open
objstream.Write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
'response.write BytesToBstr
objstream.Close
set objstream = nothing
End Function
Function Newstring(wstr,strng)
Newstring=Instr(lcase(wstr),lcase(strng))
if Newstring<=0 then Newstring=Len(wstr)
End Function

Dim wstr,str,url,start,over,dtime
url="http://127.0.0.1/a.asp" '要生成页面的网页地址
wstr=getHTTPPage(url)
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt=fso.OpenTextFile(server.mappath("/a.html"),2,True)
txt.WriteLine(wstr)
txt.Close
Set txt = Nothing
Set fso = Nothing
response.write "/a.html 创建成功!"+cstr(now())
response.write "<br>"

在你的站点要目录下