Question

易语言超级列表框读出符合编辑框条件的所有数据。

例如，人事档案表，只要输入销售部，超超级列表框就能读出销售部所有人员名单，就像自动筛选功能一样。我用的是edb数据库，原本打算用树形框，对数据分类，可惜没有可参考的实例，只能退而求其次了。

Answer 1

.版本 2

.支持库 iext

.程序集 窗口程序集1

.子程序 __启动窗口_创建完毕

.如果真 (文件是否存在 (取运行目录 () ＋ “\数据库.edb”) ＝ 假)

    创建数据库 ()

.如果真结束

打开 (取运行目录 () ＋ “\数据库.edb”, “数据库”, , , , , )

.子程序 创建数据库

.局部变量 字段, 字段信息, , "2"

字段 [1].名称 ＝ “部门”

字段 [1].类型 ＝ #文本型

字段 [1].最大文本长度 ＝ 20

字段 [2].名称 ＝ “姓名”

字段 [2].类型 ＝ #文本型

字段 [2].最大文本长度 ＝ 8

创建 (取运行目录 () ＋ “\数据库.edb”, 字段)

.子程序 _按钮1_被单击

.如果真 (编辑框1.内容 ＝ “” 或 编辑框2.内容 ＝ “”)

    信息框 (“请输入部门或姓名”, 0, )

    返回 ()

.如果真结束

置当前库 (“数据库”)

加记录 (编辑框1.内容, 编辑框2.内容)

编辑框2.内容 ＝ “”

编辑框2.获取焦点 ()

.子程序 _按钮2_被单击

.局部变量 计次, 整数型

.局部变量 部门, 文本型

.局部变量 姓名, 文本型

.局部变量 序号, 整数型

超级列表框1.全部删除 ()

序号 ＝ 0

.如果真 (编辑框1.内容 ＝ “”)

    信息框 (“请输入部门”, 0, )

    返回 ()

.如果真结束

置当前库 (“数据库”)

到首记录 ()

.计次循环首 (取记录数 (), 计次)

    部门 ＝ 读 (“部门”)

    .如果真 (部门 ＝ 编辑框1.内容)

        姓名 ＝ 读 (“姓名”)

        超级列表框1.插入表项 (-1, , , , , )

        超级列表框1.置标题 (序号, 0, 到文本 (序号 ＋ 1))

        超级列表框1.置标题 (序号, 1, 部门)

        超级列表框1.置标题 (序号, 2, 姓名)

        序号 ＝ 序号 ＋ 1

    .如果真结束

    跳过 ()

.计次循环尾 ()

Answer 2

你倒过来取数据就可以了。也就是循环从后尾取，而不是你的那个计次循环从头取数据。.版本2.变量循环首(50,1,-1,局部_计次)编辑框1.内容＝编辑框1.内容＋“20”＋到文本(正则.取匹配文本(局部_计次))＋#换行符＋#换行符'下面的内容你的源码一样，我就不写了.变量循环尾()

追问

试过了，不行