Question

asp 把表格导出excel表源码

Answer 1

一、用Excel对象，但要有Excel模板。速度略慢

<!--#include file="../conn.asp"-->
<%
dim s,sql,filename,fs,myfile,x
Set fs = server.CreateObject("scripting.filesystemobject")
'--假设你想让生成的EXCEL文件做如下的存放
filename = Server.MapPath("users.xls")
'--如果原来的EXCEL文件存在的话删除它
if fs.FileExists(filename) then
    fs.DeleteFile(filename)
end if
'--创建EXCEL文件
set myfile = fs.CreateTextFile(filename,true)
strSql = "select djh,bmmc,jihua,mubiao from scheme "
Set rstData =conn.execute(strSql)
if not rstData.EOF and not rstData.BOF then
    dim trLine,responsestr
    strLine=""
    For each x in rstData.fields
        strLine = strLine & x.name & chr(9)
    Next
'--将表的列名先写入EXCEL
    myfile.writeline strLine
    Do while Not rstData.EOF
        strLine=""
        for each x in rstData.Fields
            strLine = strLine & x.value & chr(9)
        next
        myfile.writeline strLine
        rstData.MoveNext
    loop
end if
Response.Write "生成EXCEL文件成功，点击<a href=""users.xls"" target=""_blank"">下载</a>！"
rstData.Close
set rstData = nothing
Conn.Close
Set Conn = nothing
%>

二、生成假的Excel，文件本身的格式是TXT，但扩展名使用的是XLS，用Excel也可以打开。速度快

<!--#include file="../conn.asp"-->
<%
Response.ContentType="application/vnd.ms-excel "    
%>
<table border="1"  style="border-collapse:collapse;">
    <tr align="center">
        <td>编号</td>
        <td>日期</td>
        <td>部门</td>
        <td>工作计划</td>
        <td>工作目标</td>
    </tr>
<%
set rs=server.createobject("adodb.recordset")
sql="select djh,rq,bmmc,jihua,mubiao from scheme where bmmc='"&session("bmmc")&"'"
rs.open sql,conn,1,1
do while not rs.eof
%>
    <tr>
        <td><%=rs("djh")%></td>
        <td><%=rs("rq")%></td>
        <td><%=rs("bmmc")%></td>
        <td><%=rs("jihua")%></td>
        <td><%=rs("mubiao")%></td>
    </tr>
<%
    rs.movenext
loop
%>
</table>
<%
rs.close
Conn.Close
Set Conn = nothing
%>

追问

这个我试了一下好像不行呀？

追答

什么叫好像不行？到底试验了没有？我一直在用这两种方法，不可能不行，不行的话，更多是权限设置的问题

追问

第一种方法运行后没显示，第二种显示下载，如果我网里有两张表格，可是下载的是第一张的

追答

没有显示，要找原因啊。。。。

追问

老大，能不能加 我QQ帮我看一下