Question

ansys命令流调试出错

我参照一本书来调试ansys程序，当调试到*vwriter时，出错，请问我该如何更正命令流中错误，命令流如下：
finish
*afun,deg !将三角函数的默认单位由弧度改为角度
theta=30
a=10000
b=a/2*tan(theta)
/prep7
n,1
n,2,a/2,-b
n,3,a
et,1,link1
r,1,1000
mp,ex,1,210e3
e,1,2
e,2,3
d,1,all,,,3,2 !约束1号节点的所有位移自由度，按增量2循环到3号节点来约束3号节点
f,2,fy,-1000
outpr,,1 !输出第一个载荷步的计算结果
finish
/solu
solve
finish
/post1
pldisp,2 !显示结构变形图，参数‘2’表示用虚线绘出结构的轮廓
mid_node=node(a/2,-b,0) !提取位于改坐标下的节点编号，并赋值与mid_node
*get,disp,node,mid_node,u,y !提取节点编号mid_node上的位移uy，并赋值与disp
left_el=enearn(mid_node) !提取距节点编号mid_node最近的单元编号，并赋值与left_el
etable,strs,ls,1 !编号“ls，1”表示轴向应力saxl，将各单元的轴向应力数值赋值与表strs
*get,strss,elem,left_el,etab,strs !从单元表strs中提取left_el单元的应力结果，并赋值与strss
*dim,label,char,2 !申明数组，提取计算结果， 定义2个元素的字符型数组label
*dim,value,,2,3 !定义2*3的数值型数组value
label(1)='strs_mpa','def_mm' !给字符型数组的第一个元素赋值
*vfill,value(1,1),data,1,-0.05498 !给其他数值型数组中的元素赋值
*vfill,value(1,2),data,strss,disp
*vfill,value(1,3),data,abs(strss/1),abs(disp/0.05498)
/out,ex1_1,out !将输出内容重定向到文件ex1_1.out
/com !以注释形式输出内容
/com,------------ex1_1 results comparison---------------
/com,
/com, | target | ansys | ratio
/com,
*vwrite,label(1),value(1,1),value(1,2),value(1,3)
(1x,a8,' ',f10.3,' ',f10.3,' ',1f5.3)
/com,---------------------------------------------------
/out !结束数据重定向，关闭输出文件
*list,ex1_1,out !列表显示文件ex1_1.out的内容

Answer 1

读了这个文件没有错误啊，可以正常输出out文件。
提醒一下，*WRITE命令可以用文件形式输入，好像不能在命令窗口输入。
提示In the graphical user interface,the *VWRITE command can only be executed from an external file such as /INPUT or *USE. The command is ignored.
在命令窗口输入被忽略了