Question

微机原理题目 要求有完整程序

在内存中预置两个以“$“结尾的字符串，找出每个字符串中大写字母个数，把大写字母多的字符串显示出来。要求把在字符串中找出大写字母数的程序部分写成子程序

Answer 1

        CODE  SEGMENT
              ASSUME    CS:CODE
 
        STR1  DB        'fgsfdsFGHFTRYRYTUTUTtrtyrtyrytrr5464564677474$'
        STR2  DB        '65755yut656567TRYT65ytyutytyutttHHHHHHHHHHHHHHHHHHHHHuyytu$'
 
      START:  PUSH      CS
              POP       DS
              PUSH      CS
              POP       ES
              LEA       SI,STR1
              CALL      COUNT
              MOV       CX,AX
              LEA       SI,STR2
              CALL      COUNT
              MOV       DX,AX
 
              CMP       CX,DX
              JL        @1
              MOV       AH,9
              LEA       DX,STR1
              INT       21H
              JMP       @EXIT
         @1:
              MOV       AH,9
              LEA       DX,STR2
              INT       21H
      @EXIT:
              MOV       AH,4CH
              INT       21H
 ;===================================
      COUNT:  PUSH      BX
              MOV       BX,0
              CLD
        @C1:
              LODSB
              CMP       AL,'$'
              JE        @C2
              CMP       AL,'A'
              JB        @C1
              CMP       AL,'Z'
              JA        @C1
              INC       BX
              JMP       @C1
        @C2:
              MOV       AX,BX
              POP       BX
              RET
;==================================              
        CODE  ENDS
              END       START