Question

运筹学lingo语言课程设计红光建筑设备公司生产四种型号的卷扬机，每种型号的卷扬机分别由电动机、齿轮减速

3、企业生产调运问题的优化
某建筑公司有四个建筑工地准备开工，该公司有两个金属构件生产车间，有两个仓库，内存四种规格钢材，一种规格塑钢门窗（成套使用）。仓库的钢材品种及拥有量见表3，构件车间生产的构件品种及工时消耗、单位材料消耗和生产成本见表4、表5、表6，各项目构件和钢材需求量见表7，由构件车间向各项目和由仓库向各项目运送物资的单位运费见表8。试建立并求解模型编制各车间的产品生产计划、由构件车间向各项目和由仓库向各项目、各车间的物资调运计划，使总成本为最小。
表3 仓库的钢材品种、塑钢拥有量
甲仓库 乙仓库
A型钢材(吨) 10000 7000
B型钢材(吨) 8000 4000
C型钢材(吨) 4000 9000
D型钢材(吨) 5000 6000
塑钢门窗(套) 300 300
表4 单位构件材料消耗量 单位：吨/件
A型钢材(吨) B型钢材(吨) C型钢材(吨) D型钢材(吨)
钢梁 12 15 10 20
钢架 15 20 10 15
表5 车间构件生产工时消耗表
钢梁(小时/件) 钢架(小时/件) 工时拥有量(小时)
一车间 100 180 28000
二车间 200 100 73000
表6 车间生产成本表 单位：元/件
钢梁 钢架
一车间 600 700
二车间 650 730
表7 各项目钢梁、钢架、钢材、塑钢门窗需求量表
钢梁(件) 钢架(件) A型钢材(吨) B型钢材(吨) C型钢材(吨) D型钢材(吨) 塑钢门窗(套)
项目1 50 40 100 80 70 20 80
项目2 30 60 90 50 80 10 140
项目3 100 100 30 30 90 100 120
项目4 50 80 90 70 60 70 160
项目5 40 60 20 80 40 60 50
合计 270 340 330 310 340 260 550
表8 单位物资运价表 单位：元/吨.公里 元/套.公里 元/件.公里
一车间 二车间 项目1 项目2 项目3 项目4 项目5
一车间 -- -- 60 80 150 80 70
二车间 -- -- 30 50 60 80 90
甲仓库 40 80 30 40 20 30 50
乙仓库 100 20 25 60 40 80 100

那位哥哥姐姐会解帮忙做一下非常感谢，分享一下

Answer 1

model:
sets:
warehouse/1..2/:ownership2;
factory/1..2/:ttime;
item/1..5/:demand3;
material/1..4/:;
production/1..2/:;
link1(material,warehouse):ownership1;
link2(production,material):expend;
link3(factory,production):time,cost,produce,ability;
link4(item,production):demand1;
link5(item,material):demand2;
link6(factory,item):transportcost1;
link7(factory,item,production):transport1;
link8(warehouse,factory):transportcost2;
link9(warehouse,factory,material):transport2;
link10(warehouse,item):transportcost3,transport3;
link11(warehouse,item,material):transport4;
endsets
data:
ownership1=
10000 7000
8000 4000
4000 9000
5000 6000;
ownership2=300 300;
expend=
12 15 10 20
15 20 10 15;
time=
100 180
200 100;
ttime=28000 73000;
cost=
600 700
650 730;
demand1=
50 40
30 60
100 100
50 80
40 60;
demand2=
100 80 70 20
90 50 80 10
30 30 90 100
90 70 60 70
20 80 40 60;
demand3=80 150 120 160 50;
transportcost1=
60 80 150 80 70
30 50 60 80 90;
transportcost2=
40 80
100 20;
transportcost3=
30 40 20 30 50
25 60 40 80 100;
enddata
min=@sum(link11(i,k,m):transport4(i,k,m)*transportcost3(i,k))
+@sum(link10(i,k):transport3(i,k)*transportcost3(i,k))
+@sum(link9(i,j,m):transport2(i,j,m)*transportcost2(i,j))
+@sum(link7(j,k,n):transport1(j,k,n)*transportcost1(j,k))
+@sum(link3(j,n):produce(j,n)*cost(j,n));
@for(factory(j):@for(material(m):@sum(warehouse(i):transport2(i,j,m))=@sum(production(n):produce(j,n)*expend(n,m))));
@for(production(n):@for(factory(j):@sum(item(k):transport1(j,k,n))=produce(j,n)));
@for(warehouse(i):@sum(item(k):transport3(i,k))<=ownership2(i));
@for(warehouse(i):@for(material(m):@sum(item(k):transport4(i,k,m))+@sum(factory(j):transport2(i,j,m))<=ownership1(m,i)));
@for(factory(i):@sum(production(n):produce(i,n)*time(i,n))<=ttime(i));
@for(item(k):@for(production(n):@sum(factory(j):transport1(j,k,n))=demand1(k,n)));
@for(item(k):@for(material(m):@sum(warehouse(i):transport4(i,k,m))=demand2(k,m)));
@for(item(k):@sum(warehouse(i):transport3(i,k))=demand3(k));
end