Question

svn服务器的代码可以同步到服务器吗

Answer 1

开发过程中，需要经常将SVN服务器上的代码同步到测试服务器上，一般做法，需要人工手工更新，这样很浪费工夫。下面的脚本为svn server的钩子程序，放在svn服务器上，只要代码更新，就会自动提交的测试服务器上。

使用条件：

1、SVN主机是WIN系统，如果要在LINUX的SVN主机上用，需要修改下面的代码为sh脚本，道理类似，代码不同。有需要的自行更改吧。

2、SVN主机上需要安装完整版的PUTTY安装包，而不是一个EXE.

3、测试服务器可以用putty登录

@echo off

setlocal enableDelayedExpansion

rem 本脚本实现将SVN服务器A(win环境)上提交的代码，自动上传(通过pscp)到测试环境的服务器B(linux)上，如果SVN在LINUX环境下，根据本代码自行调整。

rem svn服务器上版本库地址

set reposLoc=%1

set REV=%2

rem ---------------------------------------------------------------------- 配置开始

rem svn服务器上putty的路径

set puttyPath="D:\Program Files (x86)\PuTTY"

rem 测试环境putty登录的用户名

set username=root

rem 测试环境putty登录的密码

set password=password

rem 测试环境IP

set host=10.1.1.1

rem 测试环境代码根地址

set remoteRootPath=/var/www/htdocs/test

rem ---------------------------------------------------------------------- 配置结束

cd /d %puttyPath%

rem 遍历提交了的代码

for /f "tokens=2 delims= " %%i in ('svnlook changed %reposLoc%') do (

set "var=%%i"

svnlook cat !reposLoc! !var! > temp.txt

rem 替掉路径中的trunk

set newPath=!var:trunk=!

rem 通过pscp提交到测试服务器

echo y | pscp -l  !username! -pw !password! temp.txt !host!:!remoteRootPath!!newPath!

)

使用方法：

将上面的代码中配置区的变量修改，并将内容保存成bat文件，命名为post-commit.bat，放在SVN服务器上版本库的hooks目录下。提交代码试试看吧。经测试可行。

当然，这个脚本可以再做的牛比点儿，可以针对某个用户的提交做更新，也可以分析SVN提交时的日志，只有当日志中有特定的字符时更新。

另外，由于上面的脚本，只更新当前的提交，所以假设只针对某个用户的提交做更新时，不能只更新当前提交，这样其它用户的提交就落掉了，需要更新整个工程。