Question

你好，请问一下运筹学课程设计题：生产调运问题

课程设计选题（9）：生产调运问题
某建筑公司有5个施工项目准备开工，该公司有两个金属构件生产车间，有两个仓库，内存4种规格钢材，1种规格塑钢门窗（成套使用）。仓库的钢材品种及拥有量见表12，构件车间生产的单位构件材料消耗、工时消耗和生产成本见表13--15，各项目构件和钢材需求量见表16，由构件车间向各项目和由仓库向各项目运送物资的单位运费见表17。试建立并求解模型，编制各车间的产品生产计划、由构件车间向各项目和由仓库向各项目、各车间的物资调运计划，使总成本为最小。

Answer 1

model:
sets:
warehouse/1..2/:ownership2;
factory/1..2/:ttime;
item/1..5/:demand3;
material/1..3/:;
production/1..2/:;
link1(material,warehouse):ownership1;
link2(production,material):expend;
link3(factory,production):time,cost,produce,ability;
link4(item,production):demand1;
link5(item,material):demand2;
link6(factory,item):transportcost1;
link7(factory,item,production):transport1;
link8(warehouse,factory):transportcost2;
link9(warehouse,factory,material):transport2;
link10(warehouse,item):transportcost3,transport3;
link11(warehouse,item,material):transport4;
endsets
data:
ownership1=
5000 7000
5500 6500
10000 6000;
ownership2=380 450;
expend=
9 13 23
11 15 20;
time=
30 40
40 35;
ttime=20000 10000;
ability=
120 80
100 120;
cost=
320 300
280 360;
demand1=
80 0
100 90
100 60
60 50
30 120;
demand2=
50 30 40
0 120 100
70 120 160
40 90 30
60 90 40;
demand3=140 120 100 220 70;
transportcost1=
20 40 100 50 40
40 50 120 70 60;
transportcost2=
90 50
60 40;
transportcost3=
10 10 20 30 20
10 15 15 5 30;
enddata
min=@sum(link11(i,k,m):transport4(i,k,m)*transportcost3(i,k))
+@sum(link10(i,k):transport3(i,k)*transportcost3(i,k))
+@sum(link9(i,j,m):transport2(i,j,m)*transportcost2(i,j))
+@sum(link7(j,k,n):transport1(j,k,n)*transportcost1(j,k))
+@sum(link3(j,n):produce(j,n)*cost(j,n)+@if(produce(j,n)#gt#ability(j,n),200*(produce(j,n)-ability(j,n)),0));
@for(factory(j):@for(material(m):@sum(warehouse(i):transport2(i,j,m))=@sum(production(n):produce(j,n)*expend(n,m))));
@for(production(n):@for(factory(j):@sum(item(k):transport1(j,k,n))=produce(j,n)));
@for(warehouse(i):@sum(item(k):transport3(i,k))<=ownership2(i));
@for(warehouse(i):@for(material(m):@sum(item(k):transport4(i,k,m))+@sum(factory(j):transport2(i,j,m))<=ownership1(m,i)));
@for(factory(i):@sum(production(n):produce(i,n)*time(i,n))<=ttime(i));
@for(item(k):@for(production(n):@sum(factory(j):transport1(j,k,n))=demand1(k,n)));
@for(item(k):@for(material(m):@sum(warehouse(i):transport4(i,k,m))=demand2(k,m)));
@for(item(k):@sum(warehouse(i):transport3(i,k))=demand3(k));
end

data部分自己按你的数据改一下就行了