Question

请问您知道怎么提交xml数据到微信api接口吗

您好，请问您知道asp怎么post提交数据到微信的api接口吗？

Answer 1

我个人的公众号示例代码：

<%@Language="VBScript" CodePage="65001"%>
<%
'注意：ASP文件需要以UTF-8的格式保存,否则乱码.
'====================================
'这两行代码是为了初期通过微信Token接口验证的.
'response.write request("echostr")
'response.end

dim signature	'微信加密签名
dim timestamp	'时间戳
dim nonce		'随机数
'dim echostr		'随机字符串
dim Token
dim signaturetmp
token="xxxxx"	'您在后台添写的 token

signature = Request("signature")
nonce = Request("nonce")
timestamp = Request("timestamp")

dim ToUserName	'开发者微信号
dim FromUserName'发送方帐号（一个OpenID）
dim CreateTime	'消息创建时间（整型）
dim MsgType		'text
dim wxCont		'消息内容
dim MsgId		'消息id，64位整型

Sub getMSG()
	on error resume next
	set xDom = Server.CreateObject("MSXML2.DOMDocument")'此处根据服务器支持情况改写
	xDom.load request
	ToUserName=xDom.getelementsbytagname("ToUserName").item(0).text
	FromUserName=xDom.getelementsbytagname("FromUserName").item(0).text
	MsgType=xDom.getelementsbytagname("MsgType").item(0).text
	if MsgType="text" then wxCont=xDom.getelementsbytagname("Content").item(0).text
	if MsgType="event" then wxCont=xDom.getelementsbytagname("Event").item(0).text
	set xDom=Nothing
End sub

call getMSG()
if FromUserName="" and wxCont="" then response.end '无来源和内容，中止处理。

wxCont=replace(wxCont,chr(13),"")
wxCont=replace(wxCont,chr(10),"")
wxCont=trim(wxCont)

if wxCont="subscribe" then '表示有新的用户关注，旧接口是Hello2BizUser
	reMSG="欢迎关注<吴世昌IT技术服务>"&VBCrLf & " 主页: "&VBCrLf & "www.fj543.com"
elseIf wxCont="unsubscribe" Then	'取消订阅

elseIf wxCont="0" Then
	'处理自定义的回复代码
	reMSG="帮助说明："& VBCrLf &"回复1查看我们的网址；回复2查看联系方式；"
elseif wxCont="1" then
	reMSG="我们的网址是XXXX"
elseif wxCont="2" then
	reMSG="联系我们：XXXXX"& vbcrlf & "XXXXXX"
else '其它消息
	reMSG="感谢您的留言，我将尽快回复，请耐心等候。"
end if
reMSG=reMSG & vbcrlf& vbcrlf & "回复数字0查看帮助说明."	' & err.description

outXML="<xml>" &_
	"<ToUserName><![CDATA["&fromusername&"]]></ToUserName>" &_
	"<FromUserName><![CDATA["&tousername&"]]></FromUserName>" &_
	"<CreateTime>"& now() &"</CreateTime>" &_
	"<MsgType><![CDATA[text]]></MsgType>" &_
	"<Content><![CDATA[" & reMSG & "]]></Content>" &_
	"<FuncFlag>0<FuncFlag>" &_
	"</xml>"
response.write outXML
%>