Question

大神们求一个bat或者vbs代码：在C盘下查找删除包含某一字段（例如：123）的文件夹和文件（最好高权限）

最好能也查找删除类似下面这些：只读，隐藏，系统文件，非管理员权限的文件。





Answer 1

@echo off & title 删除名字中包含指定字段的文件（夹） By 依梦琴瑶

cd /d %~dp0
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit

::设置指定字段
set Str=123

::设置待处理目录或分区
set Src=C:\

cd /d "%Src%"

echo 搜索相关文件夹，并删除中，请等候 .....
for /r /d %%a in (*%Src%*) do (
rd /s /q "%%~a" >nul 2>nul && (
echo 删除成功 -- "%%~a"
) || (
echo 无法删除 -- "%%~a"
)
)

echo,
echo 删除相关文件中，请等候 .....
del /a /f /q /s "*%Src%*"

echo, & echo 处理完毕，请按任意键退出。
pause>nul & exit

手机编写，尚未实测，请找一些不重要的位置进行尝试。

追问

运行了几分钟之后回显是这样，最后也没删除。

追答

抱歉，代码中调用错了。

*Src*改成*Str*

粗心大意了，，正确如下：

@echo off & title 删除名字中包含指定字段的文件（夹） By 依梦琴瑶

cd /d %~dp0
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit

::设置指定字段
set Str=123

::设置待处理目录或分区
set Src=C:\

cd /d "%Src%"

echo 搜索相关文件夹，并删除中，请等候 .....
for /r /d %%a in (*%Str%*) do (
    rd /s /q "%%~a" >nul 2>nul && (
        echo 删除成功 -- "%%~a"
    ) || (
        echo 无法删除 -- "%%~a"
    )
)

echo,
echo 删除相关文件中，请等候 .....
del /a /f /q /s "*%Str%*"

echo, & echo 处理完毕，请按任意键退出。
pause>nul & exit

追问

蟹蟹蟹蟹

追答

现在应该可行了吧！手机编写，屏幕的局限性，加操作不方便，容易粗心大意。抱歉了。

@echo off & title 删除名字中包含指定字段的文件（夹） By 依梦琴瑶
 
cd /d %~dp0
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
 
::设置指定字段
set Str=123
 
::设置待处理目录或分区
set Src=C:\
 
cd /d "%Src%"
 
echo 搜索相关文件夹，并删除中，请等候 .....
for /r /d %%a in (*%Str%*) do (
    rd /s /q "%%~a" >nul 2>nul && (
        echo 删除成功 -- "%%~a"
    ) || (
        echo 无法删除 -- "%%~a"
    )
)
 
echo,
echo 删除相关文件中，请等候 .....
del /a /f /q /s "*%Str%*"
 
echo, & echo 处理完毕，请按任意键退出。
pause>nul & exit

重新发一下，以保证APP端也能更新显示新的代码。😊

追问

谢谢，这次没问题啦