Question

excel宏运行时出现运行时错误1004，应用程序定义或对象定义错误，请大神指点！！！

Private Sub Worksheet_Change(ByVal Target As Range)
Dim l_row, l_column As Long
i_row = Target.Row
i_column = Target.Column
If Target.Count = 1 Then
If Target.Column = 10 And Target.Offset(0, -2) <> "" Then
Cells(Target.Row, 17) = Target.Offset(0, -2)
ElseIf Target.Column = 10 And Target.Offset(0, -2) = "" Then
Cells(Target.Row, 17) = Date
ElseIf Target.Column = 8 And Target.Offset(0, 9) <> "" Then
Cells(Target.Row, 17) = ""
End If
End If
End Sub

提示If Target.Column = 10 And Target.Offset(0, -2) <> "" Then这一句有误。
宏能正常运行，但是每当我在第一列和第二列单元格中输入或删除时，就会出现上面的错误提示，而在其他列输入删除时没有提示。我是小白，看不出来，请各路大神指教！！！

Answer 1

Target.Offset(0, -2)表示鼠标点击位置的左边第二列，当点A、B列的时候就会报错，因为他们的左边出界了。

尽管前面有Column=10的并且条件，但是VBA不进行布尔短路，因此其他列点鼠标的时候任然会去查看左边第二列。

解决的办法是使用嵌套的If判定，我简单修改如下，可能你还需要适当微调：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim l_row As Long, l_column As Long
    i_row = Target.Row
    i_column = Target.Column
    If Target.Count = 1 Then
        If i_column = 10 Then
            If Target.Offset(0, -2) <> "" Then
                Cells(i_row, 17) = Target.Offset(0, -2)
            Else
                Cells(i_row, 17) = Date
            End If
        ElseIf i_column = 8 Then
            If Target.Offset(0, 9) <> "" Then Cells(i_row, 17) = ""
        End If
    End If
End Sub

变量定义均需要指定类型，程序代码适当进行缩减，尽量使用已经赋值的简单变量

Answer 2

Target.Offset(0, -2) 表示当前单元格向左移动两列后的对应单元格，你在第一列和第二列操作时，再左移两列，就没有单元格了。

追问

谢谢！