Question

易语言本地视频播放无法静态编译

单纯添加一个外部组件，视频然后静态编辑提示 错误(10143): 静态编译暂不支持使用了NPK或OPK支持库的程序。一般程序可以正常静态编译 我的易是5.11我想知道1.目前有那个版本的易语言支持 本地视频的静态编译2.如果当前没有版本支持，那么那个外部支持库可以做到视频的静态编译3.如果如上两种都没有 那么还有什么好的解决办法ps：我不清楚淡出的编译在打包全部文件是否有用，但据说没用，谁还有什么好的解决办法





Answer 1

视频播放器可以创建WMPlayer 对象

然后就可以编译了……（系统必须有WMPlayer播放器）
.版本 2

.程序集变量 wm, 对象

.子程序 __启动窗口_创建完毕

wm ＝ CreateWMPlayer (标签1.取窗口句柄 (), 0, 0, 标签1.宽度, 标签1.高度)
wm.写属性 (“URL”, “播放文件路径”)

.子程序 CreateWMPlayer, 对象, , 创建WMPlayer对象
.参数 父窗口句柄
.参数 左边位置, 整数型, 可空
.参数 顶边位置, 整数型, 可空
.参数 窗口宽度, 整数型, 可空
.参数 窗口高度, 整数型, 可空
.参数 窗口风格, 整数型, 可空, WS_常量
.参数 扩展风格, 整数型, 可空, WS_EX常量
.参数 返回句柄, 整数型, 参考 可空, 返回句柄
.局部变量 _wm, 对象
.局部变量 _hwnd, 整数型
.局部变量 _Style, 整数型

.如果真 (窗口风格 ＝ 0)
_Style ＝ #WS_CHILDWINDOW ＋ #WS_CLIPSIBLINGS ＋ #WS_CLIPCHILDREN ＋ #WS_VISIBLE ' 默认
.如果真结束
AtlAxWinInit ()
_hwnd ＝ CreateWindowEx (扩展风格, “AtlAxWin”, “WMPlayer.OCX”, _Style, 左边位置, 顶边位置, 窗口宽度, 窗口高度, 父窗口句柄, 0, 0, 0)
AtlAxGetControl (_hwnd, _wm)
返回句柄 ＝ _hwnd
返回 (_wm)
.版本 2

.常量 WS_CHILDWINDOW, "1073741824"
.常量 WS_VISIBLE, "268435456"
.常量 WS_CLIPSIBLINGS, "67108864"
.常量 WS_CLIPCHILDREN, "33554432"
.版本 2

.DLL命令 AtlAxWinInit, 整数型, "atl.dll", "AtlAxWinInit", , 此函数初始化承载代码ATL的控件通过注册 "AtlAxWin80" 和 "AtlAxWinLic80" 窗口选件类以及两个自定义windows消息。

.DLL命令 AtlAxGetControl, 整数型, "atl.dll", "AtlAxGetControl", , 获取一个直接接口指针。控件中包含的于原始的指定windows消息的句柄。
.参数 h, , , 一个处理到承载控件的窗口
.参数 x, 对象

.DLL命令 CreateWindowEx, 整数型, "user32", "CreateWindowExA", , CreateWindowEx函数通过扩展格式创建一个层叠的，自动弹出的（pop－up）或是一个子窗口。另外这个函数的作用与CreateWindow函数的作用相同。
.参数 dwExStyle, 整数型
.参数 lpClassName, 文本型
.参数 lpWindowName, 文本型
.参数 dwStyle, 整数型
.参数 x, 整数型
.参数 y, 整数型
.参数 nWidth, 整数型
.参数 nHeight, 整数型
.参数 hWndParent, 整数型
.参数 hMenu, 整数型
.参数 hInstance, 整数型
.参数 lpParam, 整数型