Question

两个批处理融合

我有两个批处理文件 一个实现全盘搜索某个文件。一个是获取桌面路径。怎么实现把搜索到的文件拷贝到获取到的桌面路径上？
@echo off
rem 指定待搜索的文件
set "FileName=UserSNID.txt"
echo 正在搜索文件，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\nul (
for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
echo.%%b
)
)
)
)
pause

@echo off
for /f "tokens=2,*" %%i in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop"') do Set desk=%%j
echo 你当前桌面路径是:%desk%
pause

Answer 1

@echo off
for /f "tokens=2,*" %%i in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop"') do Set desk=%%j
rem 指定待搜索的文件
set "FileName=UserSNID.txt"
echo 正在搜索文件，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
  if exist %%a:\nul (
    for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
      if /i "%%~nxb" equ "%FileName%" (
        copy /y "%%b" "%desk%\"
      )
    )
  )
)
pause

以上全部代码为合并后的代码.

追问

我擦。。。大神来了。。。我开始在找这两个批处理的时候就紧看到你的名字！！！