Question

asp+accesss问题，请问新闻时间如何设置XXXX-XX-XX而不是XXXX-X-X

asp+accesss问题，请问新闻时间如何设置XXXX-XX-XX而不是XXXX-X-X 如图2014/7/14 我想要2014/07/14 数据库格式已经改了 可是到DW里不认





Answer 1

时间格式是由你的电脑时间显示格式决定的,数据库只是提供可显示的参数
所以,你数据库格式已经改了,还不是你预期的效果

要想所有电脑端能统一显示格式
只要把时间分割成年月日三份就可以了

Answer 2

这个是不能直接输出的,在输出之前应该对日期格式进行格式化,
例如你的输出是Request.form("newstime")

应该在这里输出之前进行格式化

给你个格式化函数
'格式化日期函数
Function FormatDate(DateAndTime, para)
On Error Resume Next
Dim y, m, d, h, mi, s, strDateTime
FormatDate = DateAndTime
If Not IsNumeric(para) Then Exit Function
If Not IsDate(DateAndTime) Then Exit Function
y = CStr(Year(DateAndTime))
m = CStr(Month(DateAndTime))
If Len(m) = 1 Then m = "0" & m
d = CStr(Day(DateAndTime))
If Len(d) = 1 Then d = "0" & d
h = CStr(Hour(DateAndTime))
If Len(h) = 1 Then h = "0" & h
mi = CStr(Minute(DateAndTime))
If Len(mi) = 1 Then mi = "0" & mi
s = CStr(Second(DateAndTime))
If Len(s) = 1 Then s = "0" & s
Select Case para
Case "1"
strDateTime = y & "-" & m & "-" & d & " " & h & ":" & mi & ":" & s
Case "2"
strDateTime = y & "-" & m & "-" & d
Case "3"
strDateTime = y & "/" & m & "/" & d
Case "4"
strDateTime = y & "年" & m & "月" & d & "日"
Case "5"
strDateTime = m & "-" & d & " " & h & ":" & mi
Case "6"
strDateTime = m & "/" & d
Case "7"
strDateTime = m & "月" & d & "日"
Case "8"
strDateTime = y & "年" & m & "月"
Case "9"
strDateTime = y & "-" & m
Case "10"
strDateTime = y & "/" & m
Case "11"
strDateTime = right(y,2) & "-" &m & "-" & d & " " & h & ":" & mi
Case "12"
strDateTime = right(y,2) & "-" &m & "-" & d
Case "13"
strDateTime = m & "-" & d
Case "14"
strDateTime = y & m & d
Case Else
strDateTime = DateAndTime
End Select
FormatDate = strDateTime
End Function

使用方法:<%=FormatDate(Request.form("newstime"), 3)%>

追问

应该粘到DW什么位置

追答

1. 将函数总体插入到  你提供图片的第14行内;

2. 将<%=FormatDate(Request.form("newstime"), 3)%>写到你原来 写Request.form("newstime")的位置即可