Question

求写一个bat文件，功能是：导出 电脑上已安装的软件 的列表 以及安装路径。

注意：要有安装文件的路径，只有安装文件列表的我有，就是下面这个
@echo off
title 注册表扫描中...
mode con cols=50 lines=10
for /f "tokens=3 delims=\" %%i in ('reg query HKLM\SOFTWARE') do (
echo 当前扫描信息: HKLM\SOFTWARE\%%i
>>reglist.txt echo ++++++++++++++++++
>>reglist.txt echo 软件名称:%%i
>>reglist.txt echo ++++++++++++++++++
if not "%%i"=="Classes" for /f "tokens=4 delims=\" %%j in ('reg query HKLM\SOFTWARE\%%i 2^>nul') do (echo 软件信息: %%j>>reglist.txt)
)
echo 扫描完毕！
ping 127.0>nul
reglist.txt
会写的朋友可以参考上面的，我就是要在上面的基础上加上能读出软件安装路径的，我是备份电脑桌面用的，因为桌面图标有的我删了，所以对应的软件安装路径很难找，上面这个只能通过注册表找到软件，如果有大神可以扫描到绿色软件的就更好了！

Answer 1

@echo off&setlocal enabledelayedexpansion
cd /d %~dp0
for /f "tokens=7* delims=\" %%i in ('reg query HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall') do (
    echo 当前扫描信息: HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\%%~i
    reg export "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\%%~i" reg.$ >nul
    for /f "delims=" %%j in ('type reg.$ ^| findstr /i /c:"DisplayName" 2^>nul') do (
        set DN=%%~j
        set DN=!DN:"=!
        set !DN!
    )
    for /f "delims=" %%k in ('type reg.$ ^| findstr /i /c:"InstallLocation" 2^>nul') do (
        set IL=%%~k
        set IL=!IL:"=!
        set IL=!IL:\\=\!
        set !IL!
    )
    if not defined DisplayName set DisplayName=没有信息。
    if not defined InstallLocation set InstallLocation=没有信息。
    (echo  +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
    echo  注册表值: %%~i
    echo  软件名称: !DisplayName!
    echo  安装路径: !InstallLocation!
    echo  +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
    echo,)>>applist.txt
    set DisplayName=&set InstallLocation=&del reg.$
)
pause

Answer 2

网页链接