Question

Excel VBA 怎么知道单元格有没有被筛选出来的属性

Answer 1

这个问题，我花了许多时间来研究，终于有所收获，在这里分享给大家。

Excel(2007版) 的筛选对象及其属性关系图可以在这里看到：
http://hi.baidu.com/jamiechen/album/item/e620b7460cf848466963e540.html#

最大的麻烦是：Excel把同一个字段的筛选条件按三种不同的情况建立了不同的对象及属性结构（2003版的可能没有第三种情况，因为2003版最多只能设置2个条件）：
1个条件：直接使用 .Criteria1 属性记录此条件；
2个条件：分别直接使用 .Criteria1、.Criteria2 属性记录这两个条件；
3个及以上条件：.Criteria1变成了1个Variant对象，在其下建立 .Criteria(n) 属性集来记录这些条件，不使用 .Criteria2；

所以，在VBA中检查一个Sheet的筛选设置情况有点麻烦，我写的样例代码如下，请参考：

Sub MyMacro1()
Dim i As Integer, j As Integer, Str
'检查是否设置了自动筛选
If ActiveSheet.FilterMode = False Then
MsgBox "没有设置自动筛选，请先设置好了再试！", vbCritical
Exit Sub
End If
'On Error Resume Next
With ActiveSheet.AutoFilter.Filters
'按所有筛选字段检查
For i = 1 To .Count
'检查该字段是否有设置筛选条件
With .Item(i)
If .On Then
Select Case .Count
Case 1 '有一个筛选条件
Str = .Criteria1
MsgBox "第 " & i & " 个字段有筛选条件：" & Str & "（1 of 1）"
Case 2 '有两个筛选条件
Str = .Criteria1
MsgBox "第 " & i & " 个字段有筛选条件：" & Str & "（1 of 2）"
Str = .Criteria2
MsgBox "第 " & i & " 个字段有筛选条件：" & Str & "（2 of 2）"
Case Else '有三个及以及筛选条件
Str = .Criteria1
For j = 1 To .Count
MsgBox "第 " & i & " 个字段有筛选条件： " & Str(j) & " （" & j & " of " & .Count & "）"
Next j
End Select
End If
End With
Next i
End With
End Sub