Question

怎么让易语言编的软件移到桌面边缘自动隐藏？？

怎么让易语言编的软件移到桌面边缘自动隐藏？？像腾讯QQ一样。。。很多人给的代码都是只让他隐藏，一定要让鼠标移到隐藏位置在显示出来！！

Answer 1

我这里有一个例子，你可以看看。代码如下：插入两个时钟，自己拷贝就可以用。

.程序集 窗口程序集1
.程序集变量 移动方向, 整数型

.子程序 __启动窗口_创建完毕
移动 (取屏幕宽度 () － 580, -2, , )
时钟1.时钟周期 ＝ 100

.子程序 判断窗口是否需要缩回或伸出, 整数型
.参数 窗口, 窗口
.参数 移动方向, 整数型, 参考

' 此处用来判断窗口是否需要缩回
移动方向 ＝ 0
.如果真 (窗口.左边 ＞ 0 且 窗口.左边 ＜ 取屏幕宽度 () － 窗口.宽度)
.如果真结束
.如果 (窗口.顶边 ＜ 4 且 窗口.左边 ＞ 4 且 窗口.左边 ＜ 取屏幕宽度 () － 窗口.宽度)
.如果 (窗口.顶边 ＞ 4 － 窗口.高度 且 窗口.左边 ＞ 4)
.如果 (取鼠标水平位置 () ＞ 窗口.左边 ＋ 窗口.宽度 或 取鼠标水平位置 () ＜ 窗口.左边 或 取鼠标垂直位置 () ＞ 窗口.顶边 ＋ 窗口.高度)
移动方向 ＝ 1 ' 窗口上缩回
.否则

.如果结束

.否则

.如果结束
.如果 (取鼠标垂直位置 () ＜ 窗口.顶边 ＋ 窗口.高度 且 取鼠标水平位置 () ＞ 窗口.左边 且 取鼠标水平位置 () ＜ 窗口.左边 ＋ 窗口.宽度 且 窗口.顶边 ＜ 0)
移动方向 ＝ 2 ' 窗口上伸出
.否则

.如果结束

.否则
.如果 (窗口.左边 ＜ 4)
.如果 (窗口.左边 ＞ 4 － 窗口.宽度)
.如果 (取鼠标垂直位置 () ＜ 窗口.顶边 或 取鼠标垂直位置 () ＞ 窗口.顶边 ＋ 窗口.高度 或 取鼠标水平位置 () ＞ 窗口.宽度)
移动方向 ＝ 3 ' 窗口左缩回
.否则

.如果结束

.否则

.如果结束
.如果 (取鼠标垂直位置 () ＞ 窗口.顶边 且 取鼠标垂直位置 () ＜ 窗口.顶边 ＋ 窗口.高度 且 取鼠标水平位置 () ＜ 窗口.左边 ＋ 窗口.宽度 且 窗口.左边 ＜ 0)
移动方向 ＝ 4 ' 窗口左伸出
.否则

.如果结束

.否则
.如果 (窗口.左边 ＞ 取屏幕宽度 () － 4 － 窗口.宽度)
.如果 (窗口.左边 ＜ 取屏幕宽度 () － 4)
.如果 (取鼠标垂直位置 () ＜ 窗口.顶边 或 取鼠标垂直位置 () ＞ 窗口.顶边 ＋ 窗口.高度 或 取鼠标水平位置 () ＜ 取屏幕宽度 () ＋ 4 － 窗口.宽度)
移动方向 ＝ 5 ' 窗口右缩回
.否则

.如果结束

.否则

.如果结束
.如果 (取鼠标垂直位置 () ＞ 窗口.顶边 且 取鼠标垂直位置 () ＜ 窗口.顶边 ＋ 窗口.高度 且 取鼠标水平位置 () ＜ 窗口.左边 ＋ 窗口.宽度 且 取鼠标水平位置 () ＞ 窗口.左边 且 窗口.左边 ＞ 取屏幕宽度 () － 窗口.宽度)
移动方向 ＝ 6 ' 窗口右伸出
.否则

.如果结束

.否则

.如果结束

.如果结束

.如果结束
返回 (移动方向)

.子程序 _时钟1_周期事件

判断窗口是否需要缩回或伸出 (_启动窗口, 移动方向)
.如果 (移动方向 ≠ 0)
时钟2.时钟周期 ＝ 20
.否则
时钟2.时钟周期 ＝ 0
.如果结束

.子程序 _时钟2_周期事件
.局部变量 隐藏位置, 整数型

根据移动方向做出相应动作 (_启动窗口, 移动方向)
判断窗口是否需要缩回或伸出 (_启动窗口, 移动方向)

.子程序 根据移动方向做出相应动作
.参数 窗口, 窗口, 参考 可空
.参数 移动方向, 整数型, 参考 可空

.如果 (移动方向 ＝ 1) ' 上回缩
.如果 (窗口.顶边 ＞ 4 － 窗口.高度)
窗口.移动 (, 窗口.顶边 － (窗口.高度 － 4) ÷ 20, , ) ' 窗口伸出，请注意每移动的距离应该与窗口的最后位置成倍数
.否则

.如果结束
.如果 (窗口.顶边 ≤ 4 － 窗口.高度)
窗口.顶边 ＝ 4 － 窗口.高度
.否则

.如果结束

.否则

.如果结束
.如果 (移动方向 ＝ 2) ' 上伸出
.如果 (窗口.顶边 ＜ 0)
窗口.移动 (, 窗口.顶边 ＋ (窗口.高度 － 4) ÷ 20, , ) ' 窗口伸出，请注意每移动的距离应该与窗口的最后位置成倍数
.否则

.如果结束
.如果 (窗口.顶边 ≥ 0)
窗口.顶边 ＝ 0
.否则

.如果结束

.否则

.如果结束
.如果 (移动方向 ＝ 3) ' 左回缩
.如果 (窗口.左边 ＞ 4 － 窗口.宽度)
窗口.移动 (窗口.左边 － (窗口.宽度 － 4) ÷ 20, , , )
.否则

.如果结束
.如果 (窗口.左边 ≤ 4 － 窗口.宽度)
窗口.左边 ＝ 4 － 窗口.宽度
.否则

.如果结束

.否则

.如果结束
.如果 (移动方向 ＝ 4) ' 左伸出
.如果 (窗口.左边 ＜ 0)
窗口.移动 (窗口.左边 ＋ (窗口.宽度 － 4) ÷ 20, , , )
.否则

.如果结束
.如果 (窗口.左边 ≥ 0)
窗口.左边 ＝ 0
.否则

.如果结束

.否则

.如果结束
.如果 (移动方向 ＝ 5) ' 右回缩
.如果 (窗口.左边 ＜ 取屏幕宽度 () － 4)
窗口.移动 (窗口.左边 ＋ (窗口.宽度 － 4) ÷ 20, , , )
.否则

.如果结束
.如果 (窗口.左边 ≥ 取屏幕宽度 () － 4)
窗口.左边 ＝ 取屏幕宽度 () － 4
.否则

.如果结束

.否则

.如果结束
.如果 (移动方向 ＝ 6) ' 右伸出
.如果 (窗口.左边 ＞ 取屏幕宽度 () － 窗口.宽度)
窗口.移动 (窗口.左边 － (窗口.宽度 － 4) ÷ 20, , , )
.否则

.如果结束
.如果 (窗口.左边 ≤ 取屏幕宽度 () － 窗口.宽度)
窗口.左边 ＝ 取屏幕宽度 () － 窗口.宽度
.否则

.如果结束

.否则

Answer 2

鼠标移开自动隐藏的代码如下：

.版本 2
.支持库 xplib
.支持库 spec
.支持库 eAPI

.程序集 窗口程序集1
.程序集变量 程_是否离开窗体, 逻辑型
.程序集变量 程_透明度, 整数型

.子程序 __启动窗口_创建完毕

XP风格 (2)
程_透明度 ＝ 255
时钟1.时钟周期 ＝ 1000
' 本源码来自易语言资源网(www.5A5X.com)

.子程序 _时钟1_周期事件
.局部变量 P, 坐标_
.局部变量 R, 矩形_

取鼠标位置_ (P)
取窗口矩形_ (_启动窗口.取窗口句柄 (), R)
.如果 (P.横向位置 ＜ R.左边 或 P.横向位置 ＞ R.右边 或 P.纵向位置 ＜ R.顶边 或 P.纵向位置 ＞ R.底边)
程_是否离开窗体 ＝ 真
.否则
程_是否离开窗体 ＝ 假
' 本源码来自易语言资源网(www.5A5X.com)
调试输出 (“在”)
.如果结束
.如果 (程_是否离开窗体)
时钟1.时钟周期 ＝ 0
.判断循环首 (程_透明度 ≠ 0)
程_透明度 ＝ 程_透明度 － 5
设置窗口透明度 (_启动窗口.取窗口句柄 (), 程_透明度)
' 本源码来自易语言资源网(www.5A5X.com)
延时 (100)
处理事件 ()
.判断循环尾 ()
.否则

.如果结束

.版本 2

.数据类型 坐标_, , POINTAPI
.成员 横向位置, 整数型, , , x，横向位置
.成员 纵向位置, 整数型, , , y，纵向位置

.数据类型 矩形_, , RECT
.成员 左边, 整数型, , , Left
.成员 顶边, 整数型, , , Top
.成员 右边, 整数型, , , Right
.成员 底边, 整数型, , , Bottom

.版本 2

.DLL命令 取鼠标位置_, 整数型, "user32", "GetCursorPos"
.参数 位置, 坐标_

.DLL命令 取窗口矩形_, 整数型, "user32", "GetWindowRect"
.参数 窗口句柄, 整数型
.参数 矩形区域, 矩形_

Answer 3

就是最简单的几行代码！！ 何必看得这么累

.版本 2

.子程序 _时钟1_周期事件

.如果真 (_启动窗口.顶边 ≤ 0 且 鼠标打开 ＝ 假)
_启动窗口.顶边 ＝ －_启动窗口.高度 ＋ 3

.如果真结束
.判断开始 (取鼠标水平位置 () ＞ _启动窗口.左边 且 取鼠标水平位置 () ＜ _启动窗口.左边 ＋ _启动窗口.宽度 且 取鼠标垂直位置 () ＜ _启动窗口.高度 ＋ _启动窗口.顶边)
_启动窗口.顶边 ＝ 0
鼠标打开 ＝ 真

.默认

_启动窗口.顶边 ＝ －_启动窗口.高度 ＋ 3
鼠标打开 ＝ 假

.判断结束

Answer 4

在E语言 新建 打开易语言例程 经典例程 网友优秀作品 窗口停靠伸缩2

Answer 5

下个易语言的例程，里面有的，比赛获奖的。