Question

易语言将编辑框的内容写到记事本里，并且记事本自动换行，另外易语言一行一行的搜索记事本的内容方法，急

比方说我有一个单行的（运行多行=假）编辑框，将编辑框的内容写到记事本谁都会，但是我需要将这个编辑框的内容多次放进记事本，且自动换行，比方说，按钮1被单击，编辑框的内容写到记事本的第一行，将编辑框内容更改，再单击按钮1，编辑框的内容写到记事本的第二行，以此类推，另外，我还需要易语言从第一行开始一行一行的搜索记事本内容的方法，比方说我想知道记事本第20行的内容显示在编辑框的方法，请说细致点，最好给下源码，最近百度的分用完了，悬赏不高，表示内疚，我回答了几个问题，等到采纳了我一定提高悬赏，这个问题很急，实在是急用，谢谢各位了

Answer 1

.版本 2

.程序集 窗口程序集1

.程序集变量 储存, 文本型

.程序集变量 文本数组, 文本型, , "0"

.子程序 _按钮1_被单击

.如果真 (删首尾空 (编辑框1.内容) ＝ “”)

    信息框 (“请输入内容”, 0, )

    返回 ()

.如果真结束

储存 ＝ 储存 ＋ 编辑框1.内容 ＋ #换行符

写到文件 (取运行目录 () ＋ “\1.txt”, 到字节集 (储存))

文本数组 ＝ 分割文本 (储存, #换行符, )

标签2.标题 ＝ 到文本 (取数组成员数 (文本数组))

.子程序 __启动窗口_创建完毕

储存 ＝ 到文本 (读入文件 (取运行目录 () ＋ “\1.txt”))

文本数组 ＝ 分割文本 (储存, #换行符, )

标签2.标题 ＝ 到文本 (取数组成员数 (文本数组))

.子程序 _按钮2_被单击

.如果真 (删首尾空 (编辑框2.内容) ＝ “”)

    信息框 (“请输入内容”, 0, )

    返回 ()

.如果真结束

.如果真 (到整数 (删首尾空 (编辑框2.内容)) ＞ 取数组成员数 (文本数组))

    信息框 (“没有此行”, 0, )

    返回 ()

.如果真结束

编辑框1.内容 ＝ 文本数组 [到整数 (编辑框2.内容)]

追问

感激不尽，对了，还有一个疑问，实在抱歉，我才想起来，就是说能不能做成这样，就是把记事本里每行的内容都一一与编辑框的内容对应，如果有一行与编辑框的内容一样，就执行某些命令这样的，这个可以做到吗？实在不好意思，又给您添麻烦了

加了

Answer 2

.版本 2

.程序集 窗口程序集1

.程序集变量 hFile, 整数型

.子程序 __启动窗口_创建完毕

hFile ＝ 打开文件 (“C:\Tag.txt”, #改读, #无限制)  ' 打开文件，如果不存在就创建

.子程序 _按钮1_被单击

.如果真 (0 ＝ hFile)  ' 如果打开失败

    信息框 (“打开或创建失败”, 0, )

    返回 ()  ' 不往下执行

.如果真结束

.如果 (取反 (“” ＝ 删全部空 (编辑框1.内容)))  ' 如果编辑框内容不为空

    移到文件尾 (hFile)  ' 在后面写入，不然会覆盖前面的内容

    插入文本行 (hFile, 编辑框1.内容)  ' 插入一行

    编辑框1.内容 ＝ “”

    编辑框1.获取焦点 ()

.否则

    信息框 (“无法写进空文本”, 0, )  ' 空就不写

.如果结束

.子程序 __启动窗口_将被销毁

关闭文件 (hFile)  ' 关闭文件

楼下分割是一种方法，但是个人觉得浪费内存分配数组，直接用库函数就可以解决

追问

您的源码只能完成第一个任务，第二个好像不行，不过您打了这么多字实在是辛苦了，真的谢谢您。