Question

VB commondialog如何才能选择一个文件夹，返回其路径让我记录下来

VB commondialog如何才能选择一个文件夹，返回其路径让我记录下来，请注意不是选择文件，是选择一个文件夹，点击确认就可以通过commondialog.filename得到其路径,求各位编程高手支招吧！谢谢啦！

Answer 1

commondialog 似乎做不到这一点，可以调用API实现。

Option Explicit

Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
Private Const BIF_RETURNONLYFSDIRS = 1
Private Const MAX_PATH = 260

' 打开 Windows 的选择目录对话框
' hwnd 为窗口句柄(通常设为 Me.hwnd), Prompt 为指示字符串
Function ShowFolderSelection(ByVal hwnd As Long, ByVal Prompt As String) As String

    Dim iNull As Integer
    Dim lpIDList As Long
    Dim lResult As Long
    Dim sPath As String
    Dim udtBI As BrowseInfo

    With udtBI
        .hWndOwner = hwnd
        .lpszTitle = lstrcat(Prompt, "")
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With

    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList Then
        sPath = String$(MAX_PATH, 0)
        lResult = SHGetPathFromIDList(lpIDList, sPath)
        CoTaskMemFree lpIDList
        iNull = InStr(sPath, vbNullChar)
        If iNull Then sPath = Left$(sPath, iNull - 1)
    End If

    ShowFolderSelection = sPath

End Function

Private Sub Command1_Click()
    ShowFolderSelection Me.hwnd, "选择目录:"
End Sub

追问

那么返回的所选文件夹路径通过哪个变量记录呢

追答

ShowFolderSelection 函数的返回值，你可以随便定义一个变量来保存。
dim strPath as string
strPath = ShowFolderSelection( Me.hwnd, "选择目录:")

Answer 2

做了一例，仅供参考。朋友。
Private Sub Form_Load()
Show
Me.AutoRedraw = True
CommonDialog1.ShowOpen'注意：在打开时要选择到文件，下面的过程会自动获取你要的文件夹路径
s = CommonDialog1.FileName
s = StrReverse(s)
n = InStr(s, "\")
s = Mid(s, n + 1)
s = StrReverse(s)
Print s
End Sub

追问

谢谢你的解答，但是达不到我要的效果，因为我是想用commondialog抓取到我的文档的路径，我的文档里面一般不会有文件，必须要再次打开其中的二级文件夹才能找到文件，即使这样可以获得文件夹的路径，但是却包含了多余的信息，不是纯粹的我的文档的路径了。

追答

呵呵，帮不了你。抱歉。朋友。祝成功。