Question

VB编程 鼠标画圆

如何用VB编程
如何用鼠标画椭圆 就是一拉就有一个圆的那种

Answer 1

创建一个工程，界面上放一个PictureBox控件，控件名字叫Picture1，然后把下面的代码复制到工程中，运行查看效果。

Option Explicit

Private Type POINTAPI
        x As Long
        y As Long
End Type

Private Declare Function Ellipse Lib "gdi32" (ByVal hdc As Long, ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long

Private DrawEllipse As Boolean
Private dwPoint(1) As POINTAPI

Private Sub Form_Load()
    Picture1.ScaleMode = vbPixels
    Picture1.AutoRedraw = True
End Sub

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
    If Button = vbLeftButton Then
        DrawEllipse = True
        dwPoint(0).x = CLng(x)
        dwPoint(0).y = CLng(y)
    End If
End Sub

Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
    If DrawEllipse = True Then
        dwPoint(1).x = CLng(x)
        dwPoint(1).y = CLng(y)

        Picture1.Cls

        Ellipse Picture1.hdc, dwPoint(0).x, dwPoint(0).y, dwPoint(1).x, dwPoint(1).y

        Picture1.Refresh
    End If
End Sub

Private Sub Picture1_MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
    If Button = vbLeftButton Then
        DrawEllipse = False
    End If
End Sub

Answer 2

如果用代码``可以这样画``Private Sub Form_Click()
Dim CX, CY, Radius, Limit ' Declare variable.
ScaleMode = 7 ' 以厘米为单位。
CX = ScaleWidth / 2 ' X 位置。
CY = ScaleHeight / 2 ' Y 位置。
Circle (CX, CY), 1, RGB(Rnd * 255, Rnd * 255, Rnd * 255)
End Sub
如果手画可以~~
单击工具箱里的Shape按钮``画个长方体
单击长方体改它属性里的shape属性改成2-oval

Answer 3

高手