Question

易语言程序怎么保存列表框的数据！ 比如要保存列表框1里德所有数据 关闭重新打开后就会显示上次的列表1！

易语言程序怎么保存列表框的数据！ 比如要保存列表框1里德所有数据 关闭重新打开后就会显示上次的列表1！！
详细代码！ 思路知道 不过我是菜鸟！ 不懂用那些命令！！
怎么保存 怎么读入！ 帮帮忙 各位大牛！！

Answer 1

.版本 2

.子程序 __启动窗口_创建完毕
.局部变量 i, 整数型
.局部变量 文件号, 整数型
.局部变量 内容, 文本型

.如果真 (文件是否存在 (“数据文本.txt”) ＝ 假)
.计次循环首 (10, i)
列表框1.加入项目 (到文本 (i), )
.计次循环尾 ()
返回 ()
.如果真结束

文件号 ＝ 打开文件 (“数据文本.txt”, #读入, )
.判断循环首 (是否在文件尾 (文件号, 真) ＝ 假)
内容 ＝ 读入一行 (文件号)
.如果真 (内容 ≠ “”)
列表框1.加入项目 (内容, )
.如果真结束

.判断循环尾 ()

.子程序 _按钮1_被单击
.局部变量 计次, 整数型
.局部变量 i, 整数型
.局部变量 内容, 文本型
.局部变量 文件号, 整数型

计次 ＝ 列表框1.取项目数 ()
文件号 ＝ 打开文件 (“数据文本.txt”, #改写, )
.如果真 (文件号 ＝ 0)
信息框 (“0”, 0, )
返回 ()
.如果真结束

.计次循环首 (计次, i)
内容 ＝ 列表框1.取项目文本 (i － 1)
.如果真 (内容 ≠ “”)
插入文本 (文件号, 内容 ＋ #换行符)
.如果真结束

.计次循环尾 ()

Answer 2

逐项保存到数据库或者文本文件中，重新打开的时候再从数据库或文本文件读取。

追问

求详细代码
！

追答

.版本 2

.子程序 _窗口1_可否被关闭, 逻辑型
.局部变量 内容, 文本型
.局部变量 i, 整数型

.计次循环首 (列表框1.取项目数 (), i)
.如果 (i ＝ 1)
内容 ＝ 列表框1.取项目文本 (0)
.否则
内容 ＝ 内容 ＋ #换行符 ＋ 列表框1.取项目文本 (i － 1)
.如果结束

.计次循环尾 ()
写到文件 (取运行目录 () ＋ “\test.txt”, 到字节集 (内容))

.子程序 _窗口1_创建完毕
.局部变量 数组, 文本型, , "0"
.局部变量 i, 整数型

.如果真 (文件是否存在 (取运行目录 () ＋ “\test.txt”))
数组 ＝ 分割文本 (到文本 (读入文件 (取运行目录 () ＋ “\test.txt”)), #换行符, )
.计次循环首 (取数组成员数 (数组), i)
列表框1.加入项目 (数组 [i], )
.计次循环尾 ()

追问

还是没用 文件是写出了 可文件里什么都没有！

追答

你列表框里面有没有数据？把你改的代码和运行时的窗口截图上来。
补充，我代码里面的窗口1换成你自己的实际窗口，比如_启动窗口，不要全盘复制。运行代码之前先保存到一个目录中，否则写出的文件只是保存在临时目录中。

追问

额 知道 都改了 就是没用 你qq多少 问一下！！

Answer 3

有两种方法可以达到，
第一就是楼上说的 写到文件（）
我就不详细的说了，
第二种，就 是用易自带的数据库。
如果需要写代码的话，就追问。

追问

求代码！

追答

.版本 2

.程序集 窗口程序集1
.程序集变量 计次, 整数型

.子程序 _按钮加入数据_被单击

.计次循环首 (100, 计次) ' 这个循环是在列表框里加入数据，方便完成测试。、
列表框1.加入项目 (到文本 (计次), )
.计次循环尾 ()

.子程序 _按钮保存数据_被单击

' 这里用个笨方法吧，就不用变量了。方便你懂、 就是在加入一个 可视=假的编辑框。这样写简单点，也笨一点。
编辑框1.内容 ＝ “” ' 保存前先清空编辑框、
.如果真 (列表框1.取项目数 () ＜ 1) ' 判断列表框里是否有数据
信息框 (“列表框无数据可保存”, 0, “错误”)
返回 () ' 如果列表框里没有数据，就返回，不在往下执行、
.如果真结束

' 如果有数据，就执行以下数据、
.计次循环首 (列表框1.取项目数 (), 计次) ' 计次循环，取列表框里的数据、
编辑框1.加入文本 (列表框1.取项目文本 (计次 － 1) ＋ #换行符) ' 循环完毕之后，就把列表框里的数据全部写到编辑框里了。然后就可以保存了。
.计次循环尾 ()
' OK了，数据取出来了，现在就可以写到文件了。

写到文件 (“我要保存的数据.txt”, 到字节集 (编辑框1.内容)) ' 为什么要到字节集呢? 不解释...
' 这样写就可以保存了，读出的时候也是一样了。

.子程序 __启动窗口_创建完毕, , , 启动完毕时候开始读数据/
.局部变量 保存的数据, 文本型, , , 读入你保存过的文件。
.局部变量 数组变量, 文本型, , "0", 这个是数组变量，来记录数据的...

' 用一个变量来记录上次保存的数据、
保存的数据 ＝ 到文本 (读入文件 (“我要保存的数据.txt”))
' 在来一个数组变量吧。
数组变量 ＝ 分割文本 (保存的数据, #换行符, )
' OK了，。准备工作完成，，开始写到列表框吧，，这样总简单了吧。
.计次循环首 (取数组成员数 (数组变量), 计次)
列表框1.加入项目 (数组变量 [计次], )
.计次循环尾 ()
' Ok.完成、 写的简单点 说的罗嗦点，嘿嘿，照顾新人，怕看不懂，老鸟不要批评、
' 把代码复制到程序集里， 需要两个按钮，一个编辑框，一个列表框。你自己添加，还有需要修改按钮的名称，其他的不需要修改了。。。自己研究吧。，如果还不明白，抱歉了，不解释。
'我刚试了一下。复制进去的时候，可能会缺少一个 程序集变量 计次 整数型的 如果缺少了，自己添加。