Question

易语言超级列表框配置读写

我想做个类似于桌面整理的小工具。但是到了最后发现自己不会把超级列表框的内容保存，更不会读取...谁告诉我应该怎么做？（如果单单是保存文件没问题，关键是读取配置我就不行了...对于文本分割我不大清楚，网上也找到不少例子，都不行。超级列表框有两列，第一列是文件名，第二列是文件路径。）谁帮忙写个代码，包括写出配置文件和读取配置文件，如果能用我会追加100分。

Answer 1

用易数据库不是更好，速度也快，如果非要您说的那个代码如下：
----------------------------------------------------------------------------------------
.版本 2
.支持库 iext
.支持库 dp1

.程序集 窗口程序集1

.子程序 _保存_被单击
.局部变量 循环次数, 整数型
.局部变量 n, 整数型
.局部变量 临时数据, 文本型
.局部变量 最终数据, 字节集

循环次数 ＝ 超级列表框1.取表项数 ()
临时数据 ＝ “”
.计次循环首 (循环次数, n)
临时数据 ＝ 临时数据 ＋ 超级列表框1.取标题 (n － 1, 0) ＋ “|” ＋ 超级列表框1.取标题 (n － 1, 1) ＋ #换行符
.计次循环尾 ()
最终数据 ＝ 加密数据 (到字节集 (临时数据), “mmc”, 2)
.判断开始 (写到文件 (取运行目录 () ＋ “\liebiao.dat”, 最终数据) ＝ 真)
信息框 (“保存成功！”, 0, )
.默认
信息框 (“保存失败！”, #错误图标, )

.判断结束

.子程序 __启动窗口_创建完毕
.局部变量 临时数据, 文本型
.局部变量 临时数组, 文本型, , "0"
.局部变量 循环次数, 整数型
.局部变量 n, 整数型
.局部变量 再次分割, 文本型, , "0"
.局部变量 索引, 整数型

临时数据 ＝ 到文本 (解密数据 (读入文件 (取运行目录 () ＋ “\liebiao.dat”), “mmc”, 2))
临时数组 ＝ 分割文本 (临时数据, #换行符, )
循环次数 ＝ 取数组成员数 (临时数组)
超级列表框1.全部删除 ()
.计次循环首 (循环次数, n)
再次分割 ＝ 分割文本 (临时数组 [n], “|”, )
索引 ＝ 超级列表框1.插入表项 (-1, , , , , )
超级列表框1.置标题 (索引, 0, 再次分割 [1])
超级列表框1.置标题 (索引, 1, 再次分割 [2])
.计次循环尾 ()
信息框 (“读取数据成功！”, 0, )