Question

怎样用易语言编写这个工具

我有个朋友画漫画，我喜欢编程 但技术有限 很多知识都不懂 我想实现以下这幅图片的功能 按下一页就换图片 上一页就返回上一张图片 求高手给源码

Answer 1

.版本 2

.支持库 shell

.支持库 spec

.支持库 eAPI

.程序集 窗口程序集1

.程序集变量 图片文件, 文本型, , "0"

.程序集变量 图片序号, 整数型

.程序集变量 父目录, 文本型

.子程序 _按钮1_被单击

.如果真 (图片序号 ＝ 1)

    信息框 (“前面无图片”, 0, )

    返回 ()

.如果真结束

图片序号 ＝ 图片序号 － 1

图片框1.图片 ＝ 读入文件 (图片文件 [图片序号])

窗口自动大小 ()

.子程序 _按钮2_被单击

.如果真 (图片序号 ＝ 取数组成员数 (图片文件))

    信息框 (“后面无图片”, 0, )

    返回 ()

.如果真结束

图片序号 ＝ 图片序号 ＋ 1

图片框1.图片 ＝ 读入文件 (图片文件 [图片序号])

窗口自动大小 ()

.子程序 _按钮3_被单击

.局部变量 找到目录, 文本型

.局部变量 A, 整数型

.局部变量 后缀, 文本型

改变目录 (浏览文件夹 (“请选择保存路径”, ))

父目录 ＝ 取当前目录 ()

.如果 (组合框1.现行选中项 ＝ 0)

    后缀 ＝ “*”

.否则

    后缀 ＝ 组合框1.内容

.如果结束

找到目录 ＝ 寻找文件 (父目录 ＋ “\*.” ＋ 后缀, )

.如果真 (父目录 ≠ “”)

    .判断循环首 (找到目录 ≠ “”)

        加入成员 (图片文件, 找到目录)

        调试输出 (找到目录)

        找到目录 ＝ 寻找文件 (, )

    .判断循环尾 ()

.如果真结束

图片序号 ＝ 1

图片框1.图片 ＝ 读入文件 (图片文件 [图片序号])

窗口自动大小 ()

.子程序 __启动窗口_创建完毕

组合框1.现行选中项 ＝ 0

_按钮3_被单击 ()

.子程序 窗口自动大小

.如果真 (选择框1.选中 ＝ 真)

    .如果 (取图片宽度 (图片文件 [图片序号]) ≥ 544)

        宽度 ＝ 取图片宽度 (图片文件 [图片序号])

    .否则

        宽度 ＝ 544

    .如果结束

    高度 ＝ 取图片高度 (图片文件 [图片序号]) ＋ 100

    图片框1.宽度 ＝ 取图片宽度 (图片文件 [图片序号])

    图片框1.高度 ＝ 取图片高度 (图片文件 [图片序号])

    分组框1.顶边 ＝ 取图片高度 (图片文件 [图片序号])

.如果真结束

==================================================================

全部代码，你照着图片上的设计一个。

Answer 2

有是有 不过很简单 我没有再修改了 你要的话 我下星期给你发过去 记得留邮箱啊