Question

求ASP上传图片代码，完整点的

Answer 1

upload.inc页面
<SCRIPT RUNAT=SERVER LANGUAGE=VBSCRIPT>
dim upfileStream
Class upload
dim Form,File
Private Sub Class_Initialize
dim iStart,iFileNameStart,iFileNameEnd,iEnd,vbEnter,iFormStart,iFormEnd,theFile
dim strDiv,mFormName,mFormValue,mFileName,mFileSize,mFilePath,iDivLen,mStr
if Request.TotalBytes<1 then Exit Sub
set Form=CreateObject("Scripting.Dictionary")
set File=CreateObject("Scripting.Dictionary")
set upfileStream=CreateObject("Adodb.Stream")
upfileStream.mode=3
upfileStream.type=1
upfileStream.open
upfileStream.write Request.BinaryRead(Request.TotalBytes)

vbEnter=Chr(13)&Chr(10)
iDivLen=inString(1,vbEnter)+1
strDiv=subString(1,iDivLen)
iFormStart=iDivLen
iFormEnd=inString(iformStart,strDiv)-1
while iFormStart < iFormEnd
iStart=inString(iFormStart,"name=""")
iEnd=inString(iStart+6,"""")
mFormName=subString(iStart+6,iEnd-iStart-6)
iFileNameStart=inString(iEnd+1,"filename=""")
if iFileNameStart>0 and iFileNameStart<iFormEnd then
iFileNameEnd=inString(iFileNameStart+10,"""")
mFileName=subString(iFileNameStart+10,iFileNameEnd-iFileNameStart-10)
iStart=inString(iFileNameEnd+1,vbEnter&vbEnter)
iEnd=inString(iStart+4,vbEnter&strDiv)
if iEnd>iStart then
mFileSize=iEnd-iStart-4
else
mFileSize=0
end if
set theFile=new FileInfo
theFile.FileName=getFileName(mFileName)
theFile.FilePath=getFilePath(mFileName)
theFile.FileSize=mFileSize
theFile.FileStart=iStart+4
theFile.FormName=FormName
file.add mFormName,theFile
else
iStart=inString(iEnd+1,vbEnter&vbEnter)
iEnd=inString(iStart+4,vbEnter&strDiv)

if iEnd>iStart then
mFormValue=subString(iStart+4,iEnd-iStart-4)
else
mFormValue=""
end if
form.Add mFormName,mFormValue
end if

iFormStart=iformEnd+iDivLen
iFormEnd=inString(iformStart,strDiv)-1
wend
End Sub

Private Function subString(theStart,theLen)
dim i,c,stemp
upfileStream.Position=theStart-1
stemp=""
for i=1 to theLen
if upfileStream.EOS then Exit for
c=ascB(upfileStream.Read(1))
If c > 127 Then
if upfileStream.EOS then Exit for
stemp=stemp&Chr(AscW(ChrB(AscB(upfileStream.Read(1)))&ChrB(c)))
i=i+1
else
stemp=stemp&Chr(c)
End If
Next
subString=stemp
End function

Private Function inString(theStart,varStr)
dim i,j,bt,theLen,str
InString=0
Str=toByte(varStr)
theLen=LenB(Str)
for i=theStart to upfileStream.Size-theLen
if i>upfileStream.size then exit Function
upfileStream.Position=i-1
if AscB(upfileStream.Read(1))=AscB(midB(Str,1)) then
InString=i
for j=2 to theLen
if upfileStream.EOS then
inString=0
Exit for
end if
if AscB(upfileStream.Read(1))<>AscB(MidB(Str,j,1)) then
InString=0
Exit For
end if
next
if InString<>0 then Exit Function
end if
next
End Function

Private Sub Class_Terminate
form.RemoveAll
file.RemoveAll
set form=nothing
set file=nothing
upfileStream.close
set upfileStream=nothing
End Sub

Private function GetFilePath(FullPath)
If FullPath <> "" Then
GetFilePath = left(FullPath,InStrRev(FullPath, "\"))
Else
GetFilePath = ""
End If
End function

Private function GetFileName(FullPath)
If FullPath <> "" Then
GetFileName = mid(FullPath,InStrRev(FullPath, "\")+1)
Else
GetFileName = ""
End If
End function

Private function toByte(Str)
dim i,iCode,c,iLow,iHigh
toByte=""
For i=1 To Len(Str)
c=mid(Str,i,1)
iCode =Asc(c)
If iCode<0 Then iCode = iCode + 65535
If iCode>255 Then
iLow = Left(Hex(Asc(c)),2)
iHigh =Right(Hex(Asc(c)),2)
toByte = toByte & chrB("&H"&iLow) & chrB("&H"&iHigh)
Else
toByte = toByte & chrB(AscB(c))
End If
Next
End function
End Class

Class FileInfo
dim FormName,FileName,FilePath,FileSize,FileStart
Private Sub Class_Initialize
FileName = ""
FilePath = ""
FileSize = 0
FileStart= 0
FormName = ""
End Sub

Public function SaveAs(FullPath)
dim dr,ErrorChar,i
SaveAs=1
if trim(fullpath)="" or FileSize=0 or FileStart=0 or FileName="" then exit function
if FileStart=0 or right(fullpath,1)="/" then exit function
set dr=CreateObject("Adodb.Stream")
dr.Mode=3
dr.Type=1
dr.Open
upfileStream.position=FileStart-1
upfileStream.copyto dr,FileSize
dr.SaveToFile FullPath,2
dr.Close
set dr=nothing
SaveAs=0
end function
End Class
</SCRIPT>
upload1.asp页面
<!-- #include file="upload.inc" -->
<%
set nowupload=new upload
set file=nowupload.file("file1")
if file.fileSize>0 and file.filesize<3000000 then
'自动生成文件名
filename=now()
filename=replace(filename,"-","")
filename=replace(filename,":","")
filename=replace(filename," ","")
usefilename=filename
filename=filename+"."
filenameend=file.filename
filenameend=split(filenameend,".")
if filenameend(1)="gif" or filenameend(1)="jpg" then
filename=filename&filenameend(1)
file.saveAs Server.mappath("upload/"&filename)
if filenameend(1)="gif" then
session("filename")="upload/"&usefilename&".gif"
end if
if filenameend(1)="jpg" then
session("filename")="upload/"&usefilename&".jpg"
end if
else
%>
<table width=500 border="0">
<form name='pic' method='post' action="upload1.asp" enctype='multipart/form-data'>
<tr>
<td>
<%
response.write "文件格式不对"
response.write "<a href=uploadpic.asp>返回</a>"
%>
</td>
</tr>
</form>
</table>
<%
response.end
end if
set file=nothing
else
%>
<table width=500 border="0" bordercolor="#ececec">
<form name='pic' method='post' action=upload1.asp enctype='multipart/form-data'>
<tr>
<td>
<%
response.write "文件大小超过了限制"
response.write "<a href=uploadpic.asp>返回</a>"
%>
</td>
</tr>
</form>
</table>
<%
response.end
end if
set nowupload=nothing
%>
<table width=500 border="0" bordercolor="#ececec">
<form name='pic' method='post' action=upload1.asp enctype='multipart/form-data'>
<tr>
<td> 
</td>
</tr>
</form>
</table>
<script>
img="<%=replace(session("filename"),"upload/","")%>"
img2="../upload/<%=replace(session("filename"),"upload/","")%>"
parent.document.all.myform.photo.value=img
parent.document.all.pic.innerHTML="<img src="+img2+" width=100>"
</script>
<%
session("filename")=""
%>
uploadpic.asp页面
<table width=400 border="0" >
<form name='pic' method='post' action="upload1.asp" enctype='multipart/form-data'>
<tr>
<td>
<input type=file name="file1" size="30">
<input type=submit name="submit" value="上传">
</td>
</tr>
</form>
</table>