Question

AS3.0 让物体旋转

代码简单的写了下 可是有一个问题
一个类
package {
import flash.display.MovieClip;
import flash.events.Event;
public class Dapao extends MovieClip {
public function Dapao() {
init();
}
private function init():void {
addEventListener(Event.ENTER_FRAME,ef);
}
private function ef(e:Event):void {
var dx:Number=mouseX-this.x;
var dy:Number=mouseY-this.y;
var angle:Number=Math.atan2(dy,dx);
this.rotation=angle*180/Math.PI;
}
}
}
文档类
package {
import flash.display.Sprite;
import flash.events.Event;
public class tiaoshi extends Sprite{
private var dapao:Dapao=new Dapao();
public function tiaoshi() {
init();
}
private function init():void
{
dapao.x=stage.stageWidth/2;;
dapao.y=stage.stageHeight/2;
addChild(dapao);
}
}
}
我的想法是把 这个监听直接写在 类得里面 那么 再用文档类调用时我们岂不可以方便很多
当时 按上面得设想 写出来之后 发现 物体并不是按照鼠标与其坐标之间的夹角进行旋转 而且非常的死转不动 我Dapao类 内监听删除 重写了文档类
package {
import flash.display.Sprite;
import flash.events.Event;
public class tiaoshi extends Sprite{
private var dapao:Dapao=new Dapao();
public function tiaoshi() {
init();
}
private function init():void
{
dapao.x=stage.stageWidth/2;;
dapao.y=stage.stageHeight/2;
addChild(dapao);
addEventListener(Event.ENTER_FRAME,ef);
}
private function ef(e:Event):void {
var dx:Number=mouseX-dapao.x;
var dy:Number=mouseY-dapao.y;
var angle:Number=Math.atan2(dy,dx);
dapao.rotation=angle*180/Math.PI;
}
}
}
发现 又正常了
这是为什么 难道事件监听不能写在 普通类里 只能写在文档类里才能 正常吗？
请高手解答 上面的 普通类 是和库里的一个元件 绑定了

Answer 1

改成这样吧

package
{
import flash.display.MovieClip;
import flash.events.MouseEvent;
import flash.events.Event;

public class Dapao extends MovieClip
{
public function Dapao()
{
stage?init():addEventListener(Event.ADDED_TO_STAGE,init);
}
private function init(_evt:Event=null):void
{
stage.addEventListener(MouseEvent.MOUSE_MOVE,ef);
}
private function ef(_evt:MouseEvent):void
{
var dx:Number = _evt.localX - this.x;
var dy:Number = _evt.localY - this.y;
var angle:Number = Math.atan2(dy,dx);
this.rotation = angle * 180 / Math.PI;
}
}
}

原因是这两句出问题

trace(mouseX) //加上这句你就知道什么问题了 这个值是以影片剪辑自身注册点0点为坐标的，所以会出现莫明其妙的坐标错误
var dx:Number=mouseX-this.x;
var dy:Number=mouseY-this.y;

要不改成这样也行
var dx:Number =parent.mouseX - this.x;
var dy:Number = parent.mouseY - this.y;

改成这样也行，反正就是要以主场景的stage为标准参照

package
{
import flash.display.MovieClip;
import flash.events.Event;
import flash.display.Stage;
public class Dapao extends MovieClip
{
public function Dapao()
{
init();
}
private function init():void
{
addEventListener(Event.ENTER_FRAME,ef);
}
private function ef(e:Event):void
{
var dx:Number =stage.mouseX - this.x;
var dy:Number = stage.mouseY - this.y;
var angle:Number = Math.atan2(dy,dx);
this.rotation = angle * 180 / Math.PI;
}
}
}