Question

易语言数字组合

我想实现一个功能，如：编辑框1输入012345、编辑框2输入6789。组合框选择1时，编辑框1中的每1个数字和编辑框2中的每2个数字组合（3个数字为一组、要列出全部组合、且不重复）如：（067、078、089、069、068、079、167、178、189、169、168、179....）.当组合框选择2时，编辑框1中的每2个数字和编辑框2中的每1个数字组合（3个数字为一组、要列出全部组合、且不重复）如：（016、017、018、019、126、127、128、129....、026、027、028、029.....）当组合框选择2时，编辑框1中的每3个数字进行组合（3个数字为一组、要列出全部组合、且不重复）
这样的功能该怎么写？有源码最好 大家帮帮忙 谢谢大家了
跪求大神们帮帮忙、、、、小弟感激不尽。

Answer 1

.版本 2

.程序集 窗口程序集1

.程序集变量 数组1, 文本型, , "0"

.程序集变量 数组2, 文本型, , "0"

.程序集变量 文本, 文本型

.程序集变量 计次, 整数型

.程序集变量 计次1, 整数型

.程序集变量 计次2, 整数型

.子程序 __启动窗口_创建完毕

编辑框3.是否允许多行 ＝ 真

.计次循环首 (3, 计次)

    组合框1.加入项目 (到文本 (计次), )

.计次循环尾 ()

.子程序 _组合框1_列表项被选择

清除数组 (数组1)

清除数组 (数组2)

.计次循环首 (取文本长度 (编辑框1.内容), 计次)

    加入成员 (数组1, 取文本中间 (编辑框1.内容, 计次, 1))

.计次循环尾 ()

.计次循环首 (取文本长度 (编辑框2.内容), 计次)

    加入成员 (数组2, 取文本中间 (编辑框2.内容, 计次, 1))

.计次循环尾 ()

编辑框3.内容 ＝ “”

.如果真 (组合框1.现行选中项 ＝ 0)

    组合1 ()

    返回 ()

.如果真结束

.如果真 (组合框1.现行选中项 ＝ 1)

    组合2 ()

    返回 ()

.如果真结束

.如果真 (取数组成员数 (数组1) ＜ 3)

    返回 ()

.如果真结束

.计次循环首 (取数组成员数 (数组1), 计次)

    .变量循环首 (计次 ＋ 1, 取数组成员数 (数组1), 1, 计次1)

        .变量循环首 (计次1 ＋ 1, 取数组成员数 (数组1), 1, 计次2)

            文本 ＝ 数组1 [计次] ＋ 数组1 [计次1] ＋ 数组1 [计次2]

            编辑框3.加入文本 (文本, “ ”)

        .变量循环尾 ()

    .变量循环尾 ()

.计次循环尾 ()

.子程序 组合1

.计次循环首 (取数组成员数 (数组1), 计次1)

    .计次循环首 (取数组成员数 (数组2), 计次)

        .变量循环首 (计次 ＋ 1, 取数组成员数 (数组2), 1, 计次2)

            文本 ＝ 数组1 [计次1] ＋ 数组2 [计次] ＋ 数组2 [计次2]

            编辑框3.加入文本 (文本, “ ”)

        .变量循环尾 ()

    .计次循环尾 ()

.计次循环尾 ()

.子程序 组合2

.计次循环首 (取数组成员数 (数组1), 计次)

    .变量循环首 (计次 ＋ 1, 取数组成员数 (数组1), 1, 计次1)

        .计次循环首 (取数组成员数 (数组2), 计次2)

            文本 ＝ 数组1 [计次] ＋ 数组1 [计次1] ＋ 数组2 [计次2]

            编辑框3.加入文本 (文本, “ ”)

        .计次循环尾 ()

    .变量循环尾 ()

.计次循环尾 ()

追问

貌似不行呀

追答

怎么个不行?

追问

你把保存易文件上传下吧 谢谢 我看看是不是我软件出问题了