Question

怎么在flash里怎么画出一个圆规画圆的过程

Answer 1

以as3.0为例，最简单的画圆就是：

this.graphics .lineStyle (1,0xff0000)
this.graphics .drawCircle(100,100,100)

如果要看得到画圆的动画，首先想一想如何绘一个圆，我的思路就是绘制一个多边形，圆不就是一个很多边的多边形么。

var r:Number = 150;//园的半径 r 
this.graphics.moveTo(r+200,200);//移动画点的起始坐标。点(200,200) 是主绘图区的圆心坐标。
this.graphics.lineStyle(1.5,0xff0000);//设置线形（线条粗细，颜色）

for (var radian:Number=0.01; radian<2*Math.PI; radian+=0.01)
{
	var diP:Point = Point.polar(r,radian);//极坐标转笛卡尔坐标。
	var dx:Number = 200+diP.x;
	var dy:Number = 200+diP.y;

	this.graphics.lineTo(dx,dy);//画到某个点的坐标。
}

上面实例也只是画出了圆，没有动画，要看到动画加个帧频侦听函数就可以了。

var r: Number = 150;

const centreX: Number = 250;
const centreY: Number = 200;

var radian: Number = 0 ;
var diP: Point;
var dx: Number;
var dy: Number;

this.graphics.moveTo(r+centreX, centreY);
this.graphics.lineStyle(1.5,0x00ff00);

addEventListener(Event.ENTER_FRAME, drawcircle);
function drawcircle(e: Event): void {
	radian += 0.05;
	diP = Point.polar(r, radian);
	dx = centreX + diP.x;
	dy = centreY + diP.y;
	this.graphics.lineTo(dx, dy);
	if (radian >2* Math.PI ) {

		removeEventListener(Event.ENTER_FRAME, drawcircle);
	}
}

下面实例实是绘制扇形的动画：

var r:Number = 150;

const centreX:Number = 250;
const centreY:Number = 200;


var radian:Number = Math.PI / 10;
var diP:Point;
var dx:Number;
var dy:Number;

this.graphics.moveTo(centreX, centreY);

this.graphics.beginFill(0x00ff00, 1);

addEventListener(Event.ENTER_FRAME, drawcircle);
function drawcircle(e: Event):void
{
	radian +=  0.01;
	diP = Point.polar(r,radian);
	dx = centreX + diP.x;
	dy = centreY + diP.y;
	this.graphics.lineTo(dx, dy);
	if (radian > Math.PI - 0.01 - Math.PI / 10)
	{
		this.graphics.endFill();
		removeEventListener(Event.ENTER_FRAME, drawcircle);
	}
}