Question

vb怎么做一个设置默认保存路径

像commondialog一样，弹出文件对话框。
但是只选择到文件夹就行了，并把读取目前这个路径为默认保存路径
（只是选择默认保存的路径，而不是直接存储文件，以后自动存储文件时就可以自动存到刚选择的默认路径下）
不是VB工程保存
而是我自己做了个程序，用于用户来选择他的保存路径

Answer 1

1，点击“工程－部件”，显示“部件”对话框，将“Microsoft Common Dialog control 6.0”选中，然后确定。

2，添加工具栏中的CommonDialog控件图标，将其添加到窗体上。

3，窗体添加Command控件和Text控件，用来浏览目录和保存默认路径。

4，在Command中添加以下代码：

Private Sub Command1_Click()
CommonDialog1.DialogTitle = "选择保存目录"
CommonDialog1.Filter = "全部文件 (*.*)|*.*"
CommonDialog1.FileName = "保存目录"
CommonDialog1.FilterIndex = 2
CommonDialog1.ShowSave
If CommonDialog1.FileName <> "" Then
Text1 = Left(CommonDialog1.FileName, Len(CommonDialog1.FileName) - Len(CommonDialog1.FileTitle))
Open "C:\path.txt" For Output As #1
       Print #1, Text1 '写入默认保存路径
Close #1
End If
End Sub

Private Sub Form_Load()
On Error Resume Next
If Dir("C:\path.txt") <> "" Then
Open "C:\path.txt" For Input As #1 '自动读出默认保存路径
       Input #1, TEMPA
       Text1.Text = TEMPA
Close #1
End If
End Sub

5，以上代码就达到TEXT1控件中保存默认保存路径的目的，Command1点击选择时能保存默认路径到c:\path.txt，程序运行时，自动读出默认保存路径。

Answer 2

将第一次的路径存储到注册表里，以后存储文件直接从注册表里读取路径并存储就可以了

Answer 3

VB本身没有选项可以设定该路径,不过您可以试一下以下的一个变通方法.
1. 在开始菜单上找到启动VB的快捷方式.
Start-> Programs-> Microsoft Visual Studio 6.0-> Microsoft Visual Basic 6.0
2. 右击该快捷方式,在弹出菜单上选Properties.
3. 在Shortcut选项卡上,在Start in栏中,填入您想设的目录.

Answer 4

添加一个模块,写入下面的代码
Public Declare Function CopyFile Lib "kernel32" Alias "CopyFileA" (ByVal lpExistingFileName As String, ByVal lpNewFileName As String, ByVal bFailIfExists As Long) As Long

Public Const BIF_RETURNONLYFSDIRS = 1
Public Const BIF_DONTGOBELOWDOMAIN = 2
Public Declare Function SHBrowseForFolder Lib "shell32.dll" Alias "SHBrowseForFolderA" (LpBrowseInfo As BROWSEINFO) As Long
Public Declare Function SHGetPathFromIDlist Lib "shell32.dll" Alias "SHGetPathFromIDListA" (ByVal pidl As Long, ByVal pszPath As String) As Long
Public Type BROWSEINFO
hOwner As Long
pidlroot As Long
pszDisplayName As String
lpszTitle As String
ulFlags As Long
lpfn As Long
lparam As Long
iImage As Long
End Type
Public Function GetFolder(ByVal hWnd As Long, Optional Title As String) As String
Dim bi As BROWSEINFO
Dim pidl As Long
Dim folder As String
folder = Space(255)
With bi
If IsNumeric(hWnd) Then .hOwner = hWnd
.ulFlags = BIF_RETURNONLYFSDIRS
.pidlroot = 0
If Title <> "" Then
.lpszTitle = Title & Chr$(0)
Else
.lpszTitle = "选择目录" & Chr$(0)
End If
End With

pidl = SHBrowseForFolder(bi)
If SHGetPathFromIDlist(ByVal pidl, ByVal folder) Then
GetFolder = Left(folder, InStr(folder, Chr$(0)) - 1)
Else
GetFolder = ""
End If
End Function
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
再在一个窗体上创建一个按钮,在它的click事件中写入下列代码
Dim str
str = GetFolder(Me.hWnd, "浏览文件夹")

Answer 5

使用FolderBorwserDialog类
FolderBrowserDialog fdb=new FolderBrowserDialog
fdb.RootFolder="你所选定的默认路径"
fdb.ShowDialog()