Question

mov sp ,#70h 是什么意思?

org 0000h
ajmp main

org 000bh ;T0溢出中断入口地址•
ajmp time0

org 0020h
main: clr p1.5
mov r1,#0ffh
mov r2,#00h ;给计数器r2赋初值0

；****************************************************************
mov sp,#70h ;设置堆栈
；****************************************************************

mov tmod,#01h ;设置T0工作方式
mov th0,#3ch ;T0置计数初值
mov tl0,#0b0h
setb et0 ;允许T0溢出中断
setb ea ;cpu开中断
setb tr0 ;启动T0开始计数

wait: cjne r2,#20,wait ;定时时间未到，继续查询等待
acall light ;定时时间到，调用查表求灯光子程序
ajmp wait

;以下是查表求灯光子程序
light: mov r2,#00h ;计数器重新赋初值

inc r1 ;查表求灯光，详细解释见试验5“多位数码显示”
mov a,r1
mov dptr,#tab
movc a,@a+dptr
mov p0,a
cjne a,#0ffh,next
mov r1,#0ffh
next: ret ;子程序返回

;以下是中断服务程序
time0: inc r2 ;计数器加1
mov th0,#3ch ;重置计数初值
mov tl0,#0b0h
reti ;中断返回

tab: db 0fah,0f5h,0ebh,0d7h ;灯光变换表格
db 0afh,5fh,0aah,055h,0f0h,0fh,0ffh
end

mov sp ,#70h 是什么意思? 这条指令对前后的程序有什么影响？sp既然是堆栈指针指令，也就是说这条指令是关于堆栈的操作，那为什么没有PUSH 和pop指令出现？
这条指令的意思是不是说：其下的指令是不是在#70h以后的ram内执行？
为什么要有这条指令，没有行吗？

Answer 1

mov sp ,#70h 是用来设定栈底。
堆栈在 acall light 调用子程序时，就用到了。
另外，执行中断服务程序时，也用到了。

不仅仅是PUSH 和pop指令才用堆栈。

为什么要有这条指令，没有行吗？
－－没有，也行，堆栈的栈底，默认值是 07H。
－－但是，可能会和其它程序的使用空间发生冲突。
－－对于楼主给出的这个小程序来说，应该没有冲突。

Answer 2

那个是将栈的位置放到别的地方去.有没有用要看实际情况,一般情况下都会给个初值,因为他本身的初值是07H,不够用.

Answer 3

楼上正解，SP只是一个堆栈指针。指向的位置是RAM区的栈底，而你说的下面的指令，是程序，存放在程序存储区的。