Question

魔兽世界战士使用宏

Answer 1

我的魔兽世界武器战士键位及宏设置 v4.1
标签： 魔兽世界 武器 战士 宏 键位

现在的魔兽世界的版本是4.1. 我玩的是牛头人战士, 双天赋, 天赋1是武器, 2是防御.
我这里把我战士武器天赋的常用宏和键位设置跟大家分享一下, 希望对广大的战士朋友有帮助.
需要注意的是, 这篇文章适合一定键位修改和宏编写经验的人, 如果你还不知道宏是什么, 那么你得先去学习一下基本的宏编写, 这篇文章将不提供基本的宏编写教学.

注:
1. 键位用红字表示, 中间黑字为说明, 最后蓝字部分为宏.
2. 请注意, 之后宏里面会有比如[spec:1]这样的语句, 就是说的第一个天赋, 就是武器天赋, 当然这是我的天赋, 如果你的天赋顺序和我的不同, 那么宏也要相应更改才能使用, 请注意
3. 同样的, 如果我的武器可能和你的武器名字不一样, 你也需要改成你的武器名字才能换上它
4. [mod]是指加按SHIFT,ALT或者CTRL中任意一键, 比如在字母E的宏里面有[mod]命令, 就是SHIFT+E, 当然你也可以使用ALT+E, 或者CTRL+E.
5. 使用#showtoolip的好处的是, 你可以看当前技能的CD和说明, 并且当你使用带有[mod]的命令时, 在按下SHIFT时也同时可以看它的技能CD和说明.
6. 如果两个或两个以上[]同时出现, 表示这是或的关系; 如果一个[]里面加入逗号, 表示和的关系. 比如 "/cast [help,stance:2] 援护" 表示目标是友善并且在防御姿态时施放援护.
7. 所有"/in"的宏需要ACE2以上库文件支持,你需要ACE2库(或带有ACE2库文件的插件).

数字键1
如果目标是友方就援护,敌方就冲锋,近身再按就是上撕裂
还有就是当失去敌对目标时, 再按就是选上一个敌对目标(对应猎人假死,fs隐身等)
/cast [help,stance:2] 援护
/stopmacro [noharm]
/cast [stance:1/2] 冲锋;[stance:3] 拦截
/cast [stance:2,combat] 嘲讽
/cast 撕裂
/StartAttack [exists]
/stopmacro [harm]
/TargetLastEnemy

数字键2
第一个天赋(武器)就用致死打击,第二个天赋(防御)就用复仇
所有技能都会附带怒火中烧+英勇打击
#showtooltip
/stopmacro [noharm]
/cast [spec:1] 致死打击;复仇
/cast 怒火中烧
/cast 英勇打击
/StartAttack [exists]

数字键3
没有宏, 就是斩杀技能

数字键4
各个天赋/姿态对应的aoe技能,自动适应(比如防御姿态就用踩雷霆,狂暴姿态就转旋风斩)
所有技能都会附带顺劈斩
#showtooltip
/targetenemy [dead] [noexists]
/cast [stance:1/2] 雷霆一击; [stance:3] 旋风斩
/cast [stance:2,equipped:盾牌] 盾牌格挡
/cast !顺劈斩

数字键5
各个天赋/姿态对应的大招技能,自动适应(比如你在防御就开盾墙,战斗姿态就开反击风暴)
所有技能都会附带各种回血技能
#showtooltip
/stopmacro [noharm] [dead]
/cast [stance:1] 反击风暴;[stance:3] 鲁莽; 盾墙
/cast 集结呐喊
/use 治疗石
/cast 狂暴之怒
/cast 狂怒回复

数字键6及之后
这里我故意空了这一格,这样很容易清楚的看到前5个, 因为我的手就按1-5比较容易, 之后不是用键盘去点的了, 只是为了都是看CD.

字母R
同时换上双手武器并切换至战斗姿态, 如果已经在战斗姿态, 就压制(附带英勇打击)
我在每个切换姿态的宏里加入的停止大风车, 这样你可以不必担心大风车时间, 只需要直接换姿态就可以了(比如在战场被集火, 开着大风车想换防御姿态开盾墙)
#showtooltip
/cancelaura 剑刃风暴
/cast 战斗姿态
/cast [harm] 压制
/cast [harm] 英勇打击
/StartAttack [exists]
/equip [nomod] 耶克里克的碾压锤

字母F
同时换上单手武器+盾并切换至防御姿态
#showtooltip
/cancelaura 剑刃风暴
/cast [nomod] 防御姿态
/equipslot 16 祖利安斩骨者
/equipslot 17 源质地卫之盾
/StartAttack [exists]

字母V
同时换上双手武器并切换至狂暴姿态
#showtooltip
/cancelaura 剑刃风暴
/cast 狂暴姿态
/StartAttack [exists]
/equip [nomod] 耶克里克的碾压锤

字母E
武器天赋就断筋,防御天赋就毁灭打击,如果按住shift+E就刺耳
#showtooltip
/cast [mod] 刺耳怒吼
/cast [spec:1] 断筋; 毁灭打击
/StartAttack [harm]

字母G
武器天赋下没上盾(比如双手武器)的时候就击倒, 否则就反射法术, 如果按住shift+E就刺耳
#showtooltip
/cancelaura 剑刃风暴
/cast [mod] 碎裂投掷
/cast [spec:1,noequipped:盾牌] 击倒;法术反射

字母Q
点一下, 同时开狂暴之怒和跳, 你说我不想跳怎么办? 那就别点目的地就行了
近身后再点可以施放乘胜追击
章也绑在这个键位上了, 需要按shift+Q开启
有的时候你在跳的时候, 还在大风车转, 这样不好, 这个宏会在要跳的时候自动取消转
#showtooltip [mod]狂怒回复;英勇飞跃
/cancelaura 剑刃风暴
/cast [mod] 狂怒回复
/cast [mod] 嗜血角斗士的顽强勋章
/cast 乘胜追击
/cast 狂暴之怒
/cast 英勇飞跃
/StartAttack [harm]

字母T
武器天赋且不在防御姿态就巨人打击, 否则就缴械
开启致命平静(我觉得这个技能和巨人打击绑在一起比较好,当然你也可以改成你喜欢的其他技能), 并且去掉怒火中烧(因为怒火中烧状态下是不能开启致命平静的)
还有就是shift+T就是大风车
使用后加力量的饰品我也绑在这个键上, 等于这个技能就是一个爆发技能
#showtooltip
/cast [mod,spec:1,noequipped:盾牌] 剑刃风暴
/cast [spec:1,nostance:2] 巨人打击;缴械
/StartAttack [exists]
/stopmacro [nospec:1] [nostance:1] [noharm]
/cancelaura 怒火中烧
/use 嗜血角斗士的胜利徽章
/cast 致命平静
/cast 英勇打击

字母Y
有英勇投掷就用, 没有就普通投掷或者射击(自动判断你的远程武器)
/cast 英勇投掷
/cast !投掷
/cast !射击

字母Z
上盾的时候吼血,没盾的时候吼战斗, 并且上马
也就是说, 你只需要点一下, 就可以同上吼+上马
还有就是, 如果能飞就上鸟, 不能飞就上马, 也是自动判断的
#showtooltip
/cast [mod,equipped:盾牌] 战斗怒吼
/cast [mod,noequipped:盾牌] 命令怒吼
/cast [noequipped:盾牌] 战斗怒吼; 命令怒吼
/stopmacro [mounted]
/cast [flyable] 蓝色驭风者; 大型灰色科多兽

其他F1是破胆, F2是致命平静, F3是战争践踏

最后是一个一键吃大红+糖的保命宏, 我放在ALT+E键位上(单独设置)
#showtooltip 奇效治疗药水
/stopcasting
/use 治疗石
/stopmacro [nocombat]
/use 符文治疗药水
/use 奇效治疗药水

这些宏组合在一起的效果就是
假如 你在战场, 你每次复活只需要按一个Z,就可以同时吼力量且上马, 然后你看到你看到一个敌人, 按1冲上去, 再按1又可以撕裂, 之后按R压制, E断筋, 按2致死, 按G击倒他, 按T开致命平静和巨人打击, 拼命砍啊! 最后按3几下斩杀, 呵呵, 当然如果战士要是这么容易就能推倒敌人我们就真的再次辉煌了~
好吧, 其实这些宏最大的好处就是都在你手边上, 一按就能按到, 比如最常用,断筋E,压制R,致死2,跳Q,吼Z等等

http://blog.sina.com.cn/s/blog_538d3cf10100xhht.html

Answer 2

我是防战。。唯一用到的宏是大招全开的那个宏，而且是自己做的就/cast xxx,弄好顺序一排排下来。其它都手动的。因为现在很多职业很多技能都是触发的，而宏不能带if这样的判断字样。所以还是手动的好，不然就不是你玩游戏是游戏玩你了

Answer 3

/cast 战斗姿态
/equip 双手武器

/cast 防御姿态
/equip 单手武器
/equip 盾牌
/cast 法术反射 （以上两个pk用）

/cast 狂暴姿态
/equip 双手武器
/use 饰品
/cast 横扫
/cast 鲁莽
/cast 大风车 --FB A怪用 注意 一般用完就躺

ZS我用的就这几个宏 一般自己喜欢吧
/cast +要用的法术 /use +要用的饰品 /equip+要装备的武器

Answer 4

战士所用的宏，并不多吧，最好还是不用的好，并不是很难去操作