Question

怎么用易语言编写程序

？？？

Answer 1

方法如下：

1、安装完成后，双击易语言图标打开易语言。这里弹出了一个对话框。

2、双击中间的“windows窗口程序”新建一个程序。界面如图所示。

菜单栏：程序的各种操作及设置。

窗口编辑区：绘制界面

属性设置区：设置组件、窗口的各种属性

组件框：选择各种组件 

提示区：显示当前程序的运行、编译情况。显示对于某一命令的帮助提示。

3、在右侧组件框找到“标签”组件 选择后在界面上拖动，松开鼠标，就画出了一个标签。

4、在左侧属性栏找到“标题”属性，修改为“我的第一个程序”并敲下回车。标签的标题就更改了

5、接下来用同样的方法创建一个编辑框和一个按钮。

打出如图中的代码。或者复制以下。

.版本 2

编辑框1.内容 ＝ “你好，世界”

信息框 (“我的第一个易语言程序”, 0, )

6、双击按钮进入代码编辑页面。把输入法调为英文状态。

打出如图中的代码。或者复制以下。

.版本 2

编辑框1.内容 ＝ “你好，世界”

信息框 (“我的第一个易语言程序”, 0, )

7、点击上方三角按钮，或者单击F5运行程序查看效果。效果如图所示

8、点击按钮。弹出了一个信息框，编辑框的标题也变为了“你好，世界”我们的第一个易语言程序制作完成！

Answer 2

1、运行易语言，在窗体中添加一个标筌、一个编辑框，一个按钮。

2、双击窗体，输入以下内容：
信息框（"这是一个易语言程序。在编辑框中输入内容后，点击按钮，你会发现标簦的标题变成了了编辑框里的内容"，，）

双击按钮，输入以下内容：
标签1.标题=编辑框1.内容

3、运行，你可以看到效果了。

PS：经过上面的步骤，你已经用易语言写好了一个程序。具体的内容建议参看易语言帮助，或到网上下载相关的教程。

Answer 3

以下是坦克大战的源码：
↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓ ↓

.版本 2
.支持库 xplib
.支持库 iext2
.程序集 窗口程序集1
.程序集变量 程序集_自己标识, 整数型
.程序集变量 程序集_敌人标识, 整数型, , "5"
.程序集变量 程序集_子弹标识, 整数型
.程序集变量 程序集_敌人子弹, 整数型, , "5"
.程序集变量 程序集_消灭敌人数, 整数型
.程序集变量 程序集_开始游戏, 逻辑型
.程序集变量 程序集_子弹速度, 整数型
.程序集变量 程序集_暂停游戏, 逻辑型
.子程序 __启动窗口_创建完毕

XP风格 (2)
.子程序 _时钟1_周期事件
.判断开始 (动画框1.键是否被按下 (87) ＝ 真)
动画框1.置角度 (程序集_自己标识, 0)
动画框1.前进 (程序集_自己标识, 5)
.判断 (动画框1.键是否被按下 (83) ＝ 真)
动画框1.置角度 (程序集_自己标识, 180)
动画框1.前进 (程序集_自己标识, 5)
.判断 (动画框1.键是否被按下 (65) ＝ 真)
动画框1.置角度 (程序集_自己标识, 270)
动画框1.前进 (程序集_自己标识, 5)
.判断 (动画框1.键是否被按下 (68) ＝ 真)
动画框1.置角度 (程序集_自己标识, 90)
动画框1.前进 (程序集_自己标识, 5)
.判断 (动画框1.键是否被按下 (74) ＝ 真)
.如果真 (动画框1.是否存在 (程序集_子弹标识))
返回 ()
.如果真结束
动画物体_子弹.图片 ＝ #图片_子弹
程序集_子弹标识 ＝ 动画框1.创建物体 (动画物体_子弹, 动画框1.取物体左边 (程序集_自己标识) ＋ 20, 动画框1.取物体顶边 (程序集_自己标识) ＋ 20, , )
播放音乐 (#声音_发射, )
动画框1.置角度 (程序集_子弹标识, 动画框1.取角度 (程序集_自己标识))
动画框1.自动前进 (程序集_子弹标识, 2, 10, , , 真, 1, 真, , )
.默认
.判断结束

.子程序 _动画框1_碰撞到物体
.参数 碰撞物体标识值, 整数型
.参数 碰撞前横坐标, 整数型
.参数 碰撞前纵坐标, 整数型
.参数 被碰撞物体标识值, 整数型
.局部变量 局部_敌人物体, 动画物体
.判断开始 (动画框1.取附加文本 (被碰撞物体标识值) ＝ “敌人” 且 碰撞物体标识值 ＝ 程序集_子弹标识)
播放音乐 (#声音_爆炸, )
程序集_消灭敌人数 ＝ 程序集_消灭敌人数 ＋ 1
标签1.标题 ＝ “消灭敌人：” ＋ 到文本 (程序集_消灭敌人数) ＋ “个”
子程序_生成不重叠敌人 (被碰撞物体标识值)
动画框1.销毁物体 (碰撞物体标识值)
.判断 (动画框1.取附加文本 (碰撞物体标识值) ＝ “敌人” 且 被碰撞物体标识值 ＝ 程序集_子弹标识)
播放音乐 (#声音_爆炸, )
程序集_消灭敌人数 ＝ 程序集_消灭敌人数 ＋ 1
标签1.标题 ＝ “消灭敌人：” ＋ 到文本 (程序集_消灭敌人数) ＋ “个”
子程序_生成不重叠敌人 (碰撞物体标识值)
动画框1.销毁物体 (被碰撞物体标识值)
.判断 (碰撞物体标识值 ＝ 程序集_自己标识 且 动画框1.取附加文本 (被碰撞物体标识值) ＝ “敌人” 或 被碰撞物体标识值 ＝ 程序集_自己标识 且 动画框1.取附加文本 (碰撞物体标识值) ＝ “敌人”)
动画框1.前进 (碰撞物体标识值, -5)
.判断 (被碰撞物体标识值 ＝ 程序集_自己标识 且 动画框1.取附加文本 (碰撞物体标识值) ＝ “敌人子弹” 或 碰撞物体标识值 ＝ 程序集_自己标识 且 动画框1.取附加文本 (被碰撞物体标识值) ＝ “敌人子弹”)
动画框1.销毁物体 (程序集_自己标识)
时钟2.时钟周期 ＝ 0
播放音乐 (#声音_输了, )
信息框 (“您输了，下次加油”, #信息图标, , )
程序集_开始游戏 ＝ 假
.判断 (被碰撞物体标识值 ＝ 程序集_子弹标识 且 动画框1.取附加文本 (碰撞物体标识值) ＝ “敌人子弹” 或 碰撞物体标识值 ＝ 程序集_子弹标识 且 动画框1.取附加文本 (被碰撞物体标识值) ＝ “敌人子弹”)
播放音乐 (#声音_爆炸, )
动画框1.销毁物体 (碰撞物体标识值)
动画框1.销毁物体 (被碰撞物体标识值)
.默认
.判断结束
.如果真 (程序集_消灭敌人数 ≥ 10)
播放音乐 (#声音_赢了, )
时钟1.时钟周期 ＝ 0
时钟2.时钟周期 ＝ 0
动画框1.销毁所有物体 ()
信息框 (“恭喜，您胜利了”, #信息图标, , )
程序集_开始游戏 ＝ 假
.如果真结束

.子程序 _时钟2_周期事件
.局部变量 局部_敌人命令, 文本型, 静态, "5"
.局部变量 i, 整数型
.局部变量 局部_随机数, 整数型
.局部变量 局部_重叠物体, 整数型
.计次循环首 (取数组成员数 (程序集_敌人标识), i)
局部_随机数 ＝ 取随机数 (1, 100)
.判断开始 (局部_随机数 ＜ 75)
局部_敌人命令 [i] ＝ “上”
.判断 (局部_随机数 ＞ 75 且 局部_随机数 ＜ 85)
局部_敌人命令 [i] ＝ “左”
.判断 (局部_随机数 ＞ 85 且 局部_随机数 ＜ 95)
局部_敌人命令 [i] ＝ “右”
.判断 (局部_随机数 ＞ 95)
局部_敌人命令 [i] ＝ “下”
.默认
局部_敌人命令 [i] ＝ “发射”
.判断结束
动画框1.前进 (程序集_敌人标识 [i], 5)
局部_重叠物体 ＝ 动画框1.寻找重叠物体 (程序集_敌人标识 [i], , , “敌人”, 假)
.如果真 (局部_重叠物体 ≠ -1)
动画框1.前进 (程序集_敌人标识 [i], -5)
.如果真结束
.判断开始 (局部_敌人命令 [i] ＝ “上”)
动画框1.转向 (程序集_敌人标识 [i], 0)
.判断 (局部_敌人命令 [i] ＝ “下”)
动画框1.转向 (程序集_敌人标识 [i], 180)
.判断 (局部_敌人命令 [i] ＝ “左”)
动画框1.转向 (程序集_敌人标识 [i], -90)
.判断 (局部_敌人命令 [i] ＝ “右”)
动画框1.转向 (程序集_敌人标识 [i], 90)
.判断 (局部_敌人命令 [i] ＝ “发射”)
.如果真 (动画框1.是否存在 (程序集_敌人子弹 [i]))
返回 ()
.如果真结束
播放音乐 (#声音_发射, )
动画物体_子弹.图片 ＝ #图片_子弹
程序集_敌人子弹 [i] ＝ 动画框1.创建物体 (动画物体_子弹, 动画框1.取物体左边 (程序集_敌人标识 [i]) ＋ 20, 动画框1.取物体顶边 (程序集_敌人标识 [i]) ＋ 20, 真, “敌人子弹”)
动画框1.置类型 (程序集_敌人子弹 [i], 1)
动画框1.置角度 (程序集_敌人子弹 [i], 动画框1.取角度 (程序集_敌人标识 [i]))
动画框1.自动前进 (程序集_敌人子弹 [i], 2, 程序集_子弹速度, , , 真, 1, 真, , )
.默认
.判断结束
.计次循环尾 ()
.子程序 _动画框1_碰撞到边界, 逻辑型
.参数 物体标识值, 整数型
.参数 碰撞前横坐标, 整数型
.参数 碰撞前纵坐标, 整数型
.参数 边界类型, 整数型
动画框1.置物体位置 (物体标识值, 碰撞前横坐标, 碰撞前纵坐标, )
.子程序 子程序_生成不重叠敌人
.参数 参数_即将销毁物体, 整数型, 可空
.局部变量 i, 整数型
.局部变量 局部_时钟周期, 整数型
.计次循环首 (取数组成员数 (程序集_敌人标识), i)
.判断开始 (参数_即将销毁物体 ＝ 0)
.循环判断首 ()
动画框1.销毁物体 (程序集_敌人标识 [i])
动画物体1.图片 ＝ #图片_敌人
程序集_敌人标识 [i] ＝ 动画框1.创建物体 (动画物体1, 取随机数 (50, 450), 取随机数 (50, 350), 真, “敌人”)
动画框1.置类型 (程序集_敌人标识 [i], 1)
.循环判断尾 (动画框1.寻找重叠物体 (程序集_敌人标识 [i], , , , ) ≠ -1)
.默认
.如果真 (参数_即将销毁物体 ＝ 程序集_敌人标识 [i])
.循环判断首 ()
动画框1.销毁物体 (程序集_敌人标识 [i])
动画物体1.图片 ＝ #图片_敌人
程序集_敌人标识 [i] ＝ 动画框1.创建物体 (动画物体1, 取随机数 (50, 450), 取随机数 (50, 350), 真, “敌人”)
动画框1.置类型 (程序集_敌人标识 [i], 1)
.循环判断尾 (动画框1.寻找重叠物体 (程序集_敌人标识 [i], , , , ) ≠ -1)
返回 ()
.如果真结束
.判断结束
.计次循环尾 ()
.子程序 _按钮1_被单击
.如果真 (程序集_开始游戏 ＝ 真)
返回 ()
.如果真结束
.判断开始 (单选框1.选中)
时钟2.时钟周期 ＝ 80
程序集_子弹速度 ＝ 10
重定义数组 (程序集_敌人标识, 假, 2)
.判断 (单选框2.选中)
时钟2.时钟周期 ＝ 40
程序集_子弹速度 ＝ 7
重定义数组 (程序集_敌人标识, 假, 3)
.判断 (单选框3.选中)
时钟2.时钟周期 ＝ 5
程序集_子弹速度 ＝ 1
重定义数组 (程序集_敌人标识, 假, 5)
.默认
.判断结束
停止播放 ()
程序集_消灭敌人数 ＝ 0
标签1.标题 ＝ “消灭敌人：”
动画框1.获取焦点 ()
动画框1.销毁所有物体 ()
置随机数种子 ()
重定义数组 (程序集_敌人子弹, 假, 取数组成员数 (程序集_敌人标识))
程序集_开始游戏 ＝ 真
时钟1.时钟周期 ＝ 40
动画物体1.图片 ＝ #图片_自己
程序集_自己标识 ＝ 动画框1.创建物体 (动画物体1, 0, 0, , “自己”)
子程序_生成不重叠敌人 ()

Answer 4

你可以看看帮助文件