Question

单纯的想知道易语言如何后台模拟单击！！！！拜托了高手们！！！！！！！

Answer 1

.版本 2

.DLL命令 API_PostMessage, 整数型, "user32", "PostMessageA", , 将一条消息投递到指定窗口的消息队列。投递的消息会在Windows事件处理过程中得到处理。在那个时候，会随同投递的消息调用指定窗口的窗口函数。特别适合那些不需要立即处理的窗口消息的发送 如消息投递成功，则返回TRUE（非零）。会设置GetLastError
.参数 hwnd, 整数型, , 接收消息的那个窗口的句柄。如设为HWND_BROADCAST，表示投递给系统中的所有顶级窗口。如设为零，表示投递一条线程消息（参考PostThreadMessage）
.参数 wMsg, 整数型, , 消息标识符
.参数 wParam, 整数型, , 具体由消息决定
.参数 lParam, 整数型, , 具体由消息决定;

.DLL命令 API_发送消息, 整数型, "user32", "SendMessageA", , 调用一个窗口的窗口函数，将一条消息发给那个窗口。除非消息处理完毕，否则该函数不会返回。SendMessageBynum， ; SendMessageByString是该函数的“类型安全”声明形式 由具体的消息决定
.参数 窗口句柄, 整数型, , 要接收消息的那个窗口的句柄
.参数 信息值, 整数型, , 消息的标识符
.参数 参数一, 整数型, , 具体取决于消息
.参数 参数二, 整数型, , 具体取决于消息;

.版本 2

.程序集 窗口程序集1

.子程序 _按钮1_被单击
.局部变量 坐标位置, 整数型
.局部变量 X, 整数型
.局部变量 Y, 整数型

X ＝ 到数值 (X框.内容)
Y ＝ 到数值 (Y框.内容)

坐标位置 ＝ X ＋ Y × 65536
' 输出调试文本 (坐标位置)

' WM_MOUSEFIRST = 512 // 移动鼠标
' WM_MOUSEMOVE = 512 // 移动鼠标
' WM_LBUTTONDOWN = 513 //按下鼠标左键
' WM_LBUTTONUP = 514 //释放鼠标左键
' WM_LBUTTONDBLCLK = 515 //双击鼠标左键
' WM_RBUTTONDOWN = 516 //按下鼠标右键
' WM_RBUTTONUP = 517 //释放鼠标右键
' WM_RBUTTONDBLCLK = 518 //双击鼠标右键
' WM_MBUTTONDOWN = 519 //按下鼠标中键
' WM_MBUTTONUP = 520 //释放鼠标中键
' WM_MBUTTONDBLCLK = 521 //双击鼠标中键

' 投递消息，不等待直接返回
API_PostMessage (取窗口句柄 (), 513, 1, 坐标位置) ' 按下
API_PostMessage (取窗口句柄 (), 514, 0, 坐标位置) ' 放开

' 发送消息，消息处理完毕后返回，不知为什么，发送消息，不能被及时处理，所以会失败。
' API_发送消息 (取窗口句柄 (), 513, 1, 坐标位置) ' 按下
' API_发送消息 (取窗口句柄 (), 514, 0, 坐标位置) ' 放开

' 双狮软件工作室 TLSWR 2006.11.12

.子程序 __启动窗口_鼠标左键被按下, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型

输出调试文本 (“__启动窗口_鼠标左键被按下”)
输出调试文本 (功能键状态)
输出调试文本 (横向位置)
输出调试文本 (纵向位置)

.子程序 __启动窗口_鼠标左键被放开, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型

输出调试文本 (“__启动窗口_鼠标左键被放开”)
输出调试文本 (功能键状态)
输出调试文本 (横向位置)
输出调试文本 (纵向位置)

.子程序 __启动窗口_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型

X框.内容 ＝ 到文本 (横向位置)
Y框.内容 ＝ 到文本 (纵向位置)

追问

好强大！！！！请问您有QQ之类的联系工具吗？麻烦您了务必告诉我下，对我有启发的话有偿也是可以的！！！

追答

这个是网友的源码，不是我的，你要学会使用百度搜索，很多东西在网上找的到的。
如果这样程度的都能换钱，那编程也太好赚钱了，O(∩_∩)O~
要感谢就感谢 双狮软件工作室吧