Question

求几个法师常用宏

Answer 1

　　7.1 火冲宏
　　示例：你带着根鱼竿，正在用这个宏悠然自得的钓鱼呢，突然冒出几个敌对阵营的玩家，你一按此宏，将鱼竿换为武器。周旋过程中，不断火冲击晕鼠标指向的目标，使用组合键击晕焦点目标，不过最后还是寡不敌众被搞死了。
　　说明：如果装备鱼竿且不在战斗，则钓鱼；如果在拿着鱼竿的时候选择了敌对目标，则把鱼竿换成武器；否则，按照鼠标指向-按下组合键时的焦点目标-当前目标的顺序释放火冲
　　/equip [harm,equipped:Fishing Pole]武器名字
　　/use [equipped:Fishing pole]Fishing;[@mouseover,exists,harm][mod,@focus,exists,harm][]Fire Blast

　　Fishing pole-鱼竿
　　Fishing-钓鱼
　　Fire Blast-火冲

　　7.2 闪现宏
　　示例：在同一个冰法的战斗中，你在读冰箭，突然身中一冰环。你按下此宏，打断了正在读的冰箭(被定身无法通过移动打断施法)，闪现了出去，并在原来的位置留下了一个灵魂图腾，成功的迷惑了对手。
　　说明：打断当前施法并闪现，配合shift组合键使用火箭腰带
　　#showtooltips Blink
　　/stopcasting
　　/use Totem of Spirits
　　/use [mod:shift]6;[nomod]Blink

　　Blink-闪现
　　Totem of Spirits-灵魂图腾

　　7.3 反制宏
　　示例：你被打进了冰箱，突然对方治疗开始读一个关键的治疗法术。你猛按此宏，立刻从冰箱出来并打断了那个治疗，并且集火另一个目标。2秒后你听到“叮”的一声，又用此宏抬手在沉默结束前把治疗变羊了。
　　说明：直接按下是解除冰箱效果，并按照鼠标指向-目标的顺序释放法术反制，并将目标变羊。此时你如果切目标打，2秒后会听到叮的提示音。此时组合键+宏是将前一个目标变羊 。
　　如果不喜欢变羊功能，留下前三行和后两行即可。
　　/stopcasting
　　/cancelAura Ice Block
　　/use [nomod,@mouseover,exists,harm][]Counterspell
　　/targetlasttarget [mod]
　　/use Polymorph
　　/targetlasttarget [mod]
　　/sw 2
　　/script Stopwatch_Play();

　　Ice Block-寒冰屏障
　　Counterspell-法术反制
　　Polymorph-变形术

　　7.4 法术偷取/驱散诅咒整合宏
　　说明：按照鼠标指向-目标的顺序，根据该目标是友军还是敌军，释放驱散诅咒/法术吸取。按下alt组合键则对自己释放驱散诅咒。
　　/stopcasting
　　/use [mod:alt,@player][nomod,@mouseover,help][nomod,@target,help]Remove Curse; [mod:shift,@focus][nomod,@mouseover,harm][]Spellsteal

　　Remove Curse-驱散诅咒
　　Spellsteal-法术吸取

　　7.5 焦点变羊/设置焦点/选取敌方玩家宏
　　示例：你在乱军丛中使用此宏，将目标指向的敌人目标变羊并设置为焦点。然后攻击另一个敌人。过程中其使用了徽章解掉了变羊，你又用此宏在没有改变目标的情况下将其变羊。战斗结束，焦点死了，目标死了，你一按此宏，清除了目标和焦点，界面清爽了。下一场战斗又要开始了，你通过此宏选定了一个敌人猎人，直接无视了扑上来的宠物。
　　说明：如果目标或者焦点死了，则清除目标/焦点；有焦点，则直接变羊焦点；否则尝试选定鼠标指向的敌人目标；如果此时还没有目标，则选定最近的敌方玩家，如果没有焦点，则将其设置为焦点并变羊。任何情况下组合键+宏是将当前目标设置为焦点并变羊。
　　/cleartarget [dead][noharm]
　　/tar [@mouseover,exists,harm]
　　/targetenemyplayer [dead][noharm][noexists]
　　/clearfocus [@focus, dead]
　　/focus [@focus, noexists]
　　/focus [mod]
　　/use [@focus] Polymorph

　　Polymorph-变形术

　　7.6 冰箱宏
　　示例：你以前总是猛按冰箱，结果秒进秒出，死了。用了这个宏再也不会了
　　说明：按一下，打断当前施法进冰箱，再怎么按也不会自己出来。如果想脱离冰箱状态，可以使用前面的攻击施法宏。
　　/stopcasting
　　/use !Ice Block

　　Ice Block-寒冰屏障

　　7.7 隐身宏
　　说明：按下打断施法隐身，再怎么按也不会主动取消隐身。如果想脱离隐身状态，可以使用前面的攻击施法宏。
　　/stopcasting
　　/cast !Invisibility

　　Invisibility-隐身术

　　7.8 变羊宏/宠物跟随宏
　　说明：按下时，宠物调为被动并停止攻击跟随你。同时将当前目标变兔子。如果没有目标则选取一个敌对玩家变兔子。配合alt组合键则冰脉变兔子
　　#showtooltip Polymorph(Rabbit)
　　/targetenemyplayer [noharm][dead]
　　/use [mod:alt,harm]Icy Veins
　　/petpassive
　　/petfollow
　　/use Polymorph(Rabbit)

　　Icy Veins-冰脉
　　Polymorph(Rabbit)-变兔子

　　7.9 爆发宏
　　[color=drakblue]说明：使用饰物+各种爆发技能，如果需要可以去掉部分技能。痛苦术和冰法通用。痛苦术如果是主天赋则吸取生命，如果是副天赋则鬼魂缠身[/color]
　　/use [harm]13
　　/use [harm]14
　　/use [harm]Time Warp
　　/use [harm]Icy Veins
　　/use [harm]Demon Soul
　　/use Frostbolt
　　/use [spec:1]Drain Life
　　/use [spec:2]Haunt

　　Time Warp-时空扭曲
　　Icy Veins-冰脉
　　Demon Soul-恶魔之魂
　　Frostbolt-冰箭
　　Drain Life-吸取生命
　　Haunt-鬼魂缠身

　　7.10 做面包/吃喝宏
　　说明：直接按是坐下，配合alt组合键是吃面包，配合shift组合键是做面包。将第三行的//改为/则在按下alt时还吃春节饺子，加快回蓝速度
　　/sit
　　/use [mod:alt]Conjured Mana Cake
　　//use [mod:alt]Festival Dumplings
　　/use [mod:shift]Conjure Refreshment

　　Conjured Mana Cake-魔法蛋糕
　　Festival Dumplings-春节饺子
　　Conjure Refreshment-制作魔法面包

　　7.11 选矿宏
　　说明：按下是尝试分矿，并且选定最近的一个运河蟹。需要可以自己修改
　　/tar 运河蟹
　　/use Prospecting
　　/use Pyrite Ore
　　/use Elementium Ore

　　Prospecting-选矿
　　Pyrite Ore-燃铁矿
　　Elementium Ore-源质矿

　　7.12 整合坐骑宏
　　说明：将最远镜头距离设置为50码，在水下则尝试上海龟/海马，在不能飞的地方上马，能飞就飞
　　/script SetCVar("cameraDistanceMax", 50)
　　/use [flyable]飞行坐骑名
　　/use [swimming]深渊海马
　　/use 陆地坐骑名
　　/run UIErrorsFrame:Clear()

　　7.13 隐身逃命宏
　　说明：隐身也不一定能活下来，换了武器才能将损失降低到最小。
　　/equip [mod]鱼竿名
　　/equip [mod]廉价魔杖名
　　/use !隐身术

　　7.14 变羊喊话宏：
　　说明：在开始变羊和变羊成功的时候都喊话
　　/s 正在将%t变羊
　　/script F=F or CreateFrame("frame")F:RegisterEvent("UNIT_SPELLCAST_SUCCEEDED")F:SetScript("OnEvent",function()if arg1=="player"and arg2=="变形术"then SendChatMessage("我已变羊%t")F:SetScript("OnEvent",nil)end;end)
　　/use 变形术

　　7.15 Buff+专注宏
　　说明：2秒内按两下是按照奥术智力-法师甲的顺序释放技能。2秒后再按则又释放奥术智力。如果按下shift+宏则是释放专注魔法并给目标提示，他会感激你的~
　　/use [mod:shift]Focus Magic
　　/castsequence [nomod]reset=2 Arcane Intellect,Mage Armor
　　/run if IsShiftKeyDown() then SendChatMessage("你获得了我的<专注魔法>!","whisper",nil,UnitName("target")) end

　　Focus Magic-专注魔法
　　Arcane Intellect-奥术智力
　　Mage Armor-法师甲