Question

请高手帮忙改一下这个批处理，多谢了！

@echo off&setlocal enabledelayedexpansion
set/a n1=40,n2=40
for %%i in (txt ini) do (
for /f "delims=" %%a in ('dir/b/a-d *.%%i')do (
echo %%a&set/a m+=1,n=0
(for /f "delims=" %%b in ('type "%%a"')do (
set/a n+=1
set/p=%%b; <nul
set/a "p1=n%%n1,p2=n%%n2"
if !p1! equ 0 echo;
if !p2! equ 0 echo;&echo;&echo;
))>temp.yky
if !p1! gtr 0 echo;>>temp.yky
move temp.yky "%%a")
)
上面这个批处理是将一个文件夹中所有文本（每个有数十到数百邮箱地址，排成一纵列）中的邮箱地址后面都加上分号，每40个地址一组，每组后面加三个空行。
我现在想增加一项：在每组地址前加一个组号，有多少组就加多少号，像下面这样。麻烦高手帮帮忙，把改好的批处理贴在下面，谢谢了！

1
abc123@163.com；sdf456@163.com；.....

2
abc123@163.com；sdf456@163.com；.....

3
abc123@163.com；sdf456@163.com；.....

......

Answer 1

呵呵,在我那代码上改动过嘛

@echo off&setlocal enabledelayedexpansion
set/a n1=40
set ext=*.ini *.txt
for /f "delims=" %%a in ('dir/b/a-d %ext%')do (
echo %%a&set/a m+=1,n=0,n2=1
(for /f "delims=" %%b in ('type "%%a"')do (
set/a "n+=1,p=n%%n1"
if !p! equ 1 (
if !n2! gtr 1 echo;&echo;&echo;
echo !n2!)
set/p=%%b;<nul
if !p! equ 0 echo;&set/a n2+=1
))>temp.yky
if !p! gtr 0 echo;>>temp.yky
move/y temp.yky "%%a")
pause
补充:看说明的空三行,刚看样文又没空那多, 把那行
if !n2! gtr 1 echo;&echo;&echo;
去掉一个 &echo; 就会少空一行,自己改...

Answer 2

不知道