Question

求bat代码，文件批量重命名

我这个批量重命名比较特殊，不是普通的批量重命名。因为有些时候windows里面和其他软件的按照日期重命名顺序不一样，但是windows的正确，所以我要先在windows里面按照时间顺序排列以后，f2批量重命名，再用其他软件重新批量命名。现在的问题是windows批量重命名格式跟其他软件不一样，位数不对，所以再其他软件了无法正确显示。比如：
windows显示的顺序（正确的顺序）是：
acd
acd (1)
acd (2)
acd (3)
acd (4)
acd (5)
acd (6)
acd (7)
acd (8)
acd (9)
acd (10)
acd (11)
acd (12)
acd (13)
acd (14)
acd (15)

其他软件显示的顺序是：
acd (1)
acd (10)
acd (11)
acd (12)
acd (13)
acd (14)
acd (15)
acd (2)
acd (3)
acd (4)
acd (5)
acd (6)
acd (7)
acd (8)
acd (9)
acd

现在我想求一段bat代码，按照windows里的顺序重新批量命名，比如：
acd 000001
acd 000002
acd 000003
acd 000004
acd 000005
acd 000006
acd 000007
acd 000008
acd 000009
acd 000010
acd 000011
acd 000012
acd 000013
acd 000014
acd 000015
acd 000016

Answer 1

看看生成的批处理脚步是否符合你的要求，符和再运行。
@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1-3 delims=()" %%i in ('dir/b acd*') do (
set/a n=%%j+1
set fn=00000!n!
echo !fn!
set fn=!fn:~-6,6!
echo !fn!
if "%%j" neq "" (echo copy %%i(%%j^)%%k "acd !fn!%%k")else echo copy %%i%%k "acd !fn!%%k"
))>renren.bat
notepad renren.bat

追问

不行啊吗，麻烦您修改一下，我不会bat

追答

怎么不行？
运行后打开记事本了吗？
记事本里有内容吗？

追问

记事本里有内容，但是文件名没有变，又产生一个rename.bat，运行这个产生一个acd000001文件，您可以创建一个文件夹，里面创建一些文件，然后全选-f2--输入acd-回车就行了，您可以随时验证代码

Answer 2

为防搞错给你新建了一文件夹 newd
@echo off&setlocal enabledelayedexpansion
set str=acd
set/a n=1000000
md newd 2>nul
for /f "delims=" %%i in ('dir/b/od %str%*')do (
echo %%i
set/a n+=1
copy "%%i" "newd\%str% !n:~-6!%%~xi">nul)
start newd

追问

非常好用!！！！麻烦再给一个不创建新文件夹的吧！

追答

@echo off&setlocal enabledelayedexpansion
set str=acd
set/a n=1000000
for /f "delims=" %%i in ('dir/b/od %str%*')do (
echo %%i
set/a n+=1
ren "%%i" "%str% !n:~-6!%%~xi" 2>nul||(
set flg=y
ren "%%i" "%str% !n:~-6!%%~xi.yky"))
if defined flg ren "*.yky" "*."
set/a n-=1000000
echo %n% 个文件已重命名
pause

Answer 3

修改一下FOR循环的起止数字,不要从1开始,从1000001开始,然后从第二位开始截取到最后就可以了.
改一下你原有的批处理应该就能用.

追问

我不会bat代码，也没有“原有的批处理”，请看清题目，我都是软件改的