Question

易语言 取随机名字（自己指定的汉字），不重复 。 这个要怎么写

Answer 1

　　可以通过计次循环得到一串字符串，达到你想要的结果。

　　以下提供的代码具有通用性。

　　代码如下：

.版本 2

.子程序 取随机长度文本, 文本型
.参数 取汉字的文本, 文本型
.参数 取出的数目, 整数型
.局部变量 Temp, 整数型
.局部变量 取出的文本, 文本型

置随机数种子 ()
.计次循环首 (取出的数目, )
    取出的文本 ＝ 取出的文本 ＋ 取文本中间 (取汉字的文本, 取随机数 (1, 取文本长度 (取汉字的文本) ÷ 2) × 2 － 1, 2)
.计次循环尾 ()
返回 (取出的文本)

　　调用代码如下（实例）：

编辑框_输出结果.内容 ＝ 取随机长度文本 (编辑框_姓.内容, 到整数 (编辑框_姓长度.内容)) ＋ 取随机长度文本 (编辑框_名.内容, 到整数 (编辑框_名长度.内容))

　　在我的演示程序中，演示结果如下：

　　如果你不想让字重复，请使用以下代码，此代码同样具有通用性：

.版本 2

.子程序 取随机长度文本, 文本型
.参数 取汉字的文本, 文本型
.参数 取出的数目, 整数型
.局部变量 Temp, 整数型
.局部变量 临时文本, 文本型
.局部变量 随机文本, 文本型
.局部变量 取出的文本, 文本型

置随机数种子 ()
临时文本 ＝ 取汉字的文本
.计次循环首 (取出的数目, )
    随机文本 ＝ 取文本中间 (临时文本, 取随机数 (1, 取文本长度 (临时文本) ÷ 2) × 2 － 1, 2)
    取出的文本 ＝ 取出的文本 ＋ 随机文本
    临时文本 ＝ 子文本替换 (临时文本, 随机文本, “”, , , 真)
.计次循环尾 ()
返回 (取出的文本)

　　此代码即符合你的要求。

　　如有疑问请追问。

追问

很厉害，可这不是我要的效果，我要的是自己指定的汉字的。 比如：“安卓”，"安装"。 随机取这两个汉字。

追答

　　如果是这样，那么效果也很容易实现。可以通过按长度保存到数组，最后随机取出的方法。

　　代码如下：

.版本 2

.子程序 取随机长度文本, 文本型
.参数 取汉字的文本, 文本型
.参数 取出的数目, 整数型
.局部变量 Temp, 整数型
.局部变量 临时文本, 文本型
.局部变量 随机文本, 文本型
.局部变量 取出的文本, 文本型, , "0"

置随机数种子 ()
临时文本 ＝ 取汉字的文本
.计次循环首 (取文本长度 (取汉字的文本) ÷ 2 ÷ 取出的数目, Temp)
    随机文本 ＝ 取文本中间 (临时文本, 1 ＋ 取出的数目 × (Temp － 1) × 2, 取出的数目 × 2)
    加入成员 (取出的文本, 随机文本)
.计次循环尾 ()
.如果真 (取数组成员数 (取出的文本) ≥ 1)
    返回 (取出的文本 [取随机数 (1, 取数组成员数 (取出的文本))])
.如果真结束
返回 (“”)

　　这段代码在我的程序中演示效果如下：

　　效果即符合你的要求。

　　如有疑问请继续追问。