Question

高分求解答，单片机编程问题，30分，好的再加分

2.设单片机主频12MHZ，使用T0计数，并口P0驱动一个数码管，循环显示0-f计数信息，每三次计数输入信号计数显示加1，程序最好带有解释，谢谢了
实验的单片机为C51

Answer 1

;单片机主频12MHz，P0驱动一个数码管，循环显示0-f计数信息，

;使用T0计数，每三次计数输入信号计数显示加1

;-------------------------------------

      ORG   0000H

      LJMP  START

      ORG   000BH

      LJMP  T0_INT

      ORG   0030H

;-------------------------------------

START:

      MOV   TMOD, #06H    ;T0计数方式2

      MOV   TH0, #(256-3) ;计数值为3

      MOV   TL0, #(256-3)

      SETB  TR0

      SETB  ET0

      SETB  EA

      MOV   P0, #0C0H

      SJMP  $

;-------------------------------------

T0_INT:

      INC   R7

      CJNE  R7, #16, DISP

      MOV   R7, #0

DISP:

      MOV   A, R7

      MOV   DPTR, #TABLE

      MOVC  A, @A+DPTR

      MOV   P0,  A

T0_END:

      RETI

;-------------------------------------

TABLE:  DB 0C0H,0F9H,0A4H,0B0H, 99H ;//共阳极0-4显示代码

        DB  92H, 82H,0F8H, 80H, 90H ;5~9

        DB  88H, 83H,0C6H,0A1H, 86H, 8EH ;A~F

END

追问

大哥 ，能用C写不 ，麻烦了 ，汇编没学过 呵呵

追答

呵呵，C语言的程序，也编写出来了。
因为你没有提出这样的要求，就没有显示在这里。
你可以看看：
http://zhidao.baidu.com/question/363320007.html

追问

看到了 ，谢谢

Answer 2

你把计数器的使用看明白，就可以做了