Question

actionscript3.0的匀速直线运动代码！

如图！ 我想a做匀速直线运动到b的位置 用代码来完成！ 该怎么写呢？ 希望回答的人是自己写的代码 不要在网上复制来的  希望能有详细的注释！万分感谢！

Answer 1

//在舞台上放置一个影片剪辑实例（小球），命名为ball。让小球直线匀速移动到鼠标点击位置。
//targetX和targetY变量用于保存鼠标点击舞台的坐标，也就是小球移动的目标位置。
var targetX:Number;
var targetY:Number;
//speed整型变量为移动速度，可以自行修改，数值大就移动快。
var speed:uint = 5;
//distance用来计算保存小球当前位置到目标位置的直线距离。
var distance:Number;
//angle用来计算保存运动线路的角度
var angle:Number
//舞台侦听鼠标键按下时间，调用getPoint函数。
stage.addEventListener(MouseEvent.MOUSE_DOWN, getPoint);
//定义getPoint函数
function getPoint(evt:MouseEvent):void{
//获取按下鼠标时的坐标
targetX = evt.stageX;
targetY = evt.stageY;
//侦听ENTER_FRAME事件，每一帧调用一次moveToPoint函数
stage.addEventListener(Event.ENTER_FRAME, moveToPoint);
}
//定义moveToPoint函数
function moveToPoint(evt:Event):void{
//计算角度
angle = Math.atan2(targetY-ball.y, targetX-ball.x);
//计算距离
distance = Math.sqrt(Math.pow(targetX-ball.x, 2) + Math.pow(targetY-ball.y, 2));
//判断：如果距离大于speed值，则移动一步；否则直接将小球移动到目标位置。
if (distance > speed){
ball.x += speed*Math.cos(angle);
ball.y += speed*Math.sin(angle);
}else{
ball.x = targetX;
ball.y = targetY;
//小球到达目标位置后停止ENTER_FRAME侦听
stage.removeEventListener(Event.ENTER_FRAME, moveToPoint);
}
}

//需要源文件的话，留下你的邮箱地址，我发给你。

Answer 2

没分没真相