Question

批处理从文件夹中搜索TXT内所列文件名文件复制到指定路径，完成后把未搜索到的文件名保存至新的TXT中

满意送高分啊~！！！
比方说有个TXT里面是我想要的歌曲名123.MP3，sho.mp3，sndhu.mp3......
，从我的硬盘中根据歌曲名“123,sho,sndhu.....”去找,并把想要的歌曲复制到指定文件夹中，搜索完成后，TXT中没有找到的歌曲名保存到a.TXT中

Answer 1

批处理搜索效率很低，现在很多音乐软件可以自动搜索硬盘，归类音乐的。
我也能给一个，你试试看。
说明：
1、第3句 (c d e f g) 可以自己设定搜索盘符，空格隔开；
2、歌曲文件列表用list.txt，放在脚本同目录中。

@echo off
for /f "delims=" %%a in (list.txt) do set "#%%a=1"
for %%d in (c d e f g h) do (
pushd %%d:
for /f "delims=" %%a in ('dir /s /b *.mp3 *.wma ^|findstr /i /g:list.txt') do (
set "#%%~nxa="
copy "%%a" "d:\myMusic\" /y
)
popd
)
for /f "tokens=1 delims=#=" %%a in ('set #') do echo,%%a>>a.txt

追问

如果我要从多区域去寻找的话该怎么办？比方说我要从C:\MUSIC\MP3这个路径以及d:\mp3\sc,e:\music\dir这几个路径查找

追答

改为这样，路径带空格的要加引号，盘符带冒号，如 "c:\a b" , d:
@echo off
for /f "delims=" %%a in (list.txt) do set "#%%a=1"
for %%d in (
C:\MUSIC\MP3
d:\mp3\sc
e:\music\dir
"f:\my music"
g:
) do (
pushd %%d
for /f "delims=" %%a in ('dir /s /b *.mp3 *.wma ^|findstr /i /g:list.txt') do (
set "#%%~nxa="
copy "%%a" "d:\myMusic\" /y
)
popd
)
for /f "tokens=1 delims=#=" %%a in ('set #') do echo,%%a>>a.txt