Question

易语言检测是否安装了某个程序

怎样检测是否安装了某个程序，如果安装了，我想用按钮来启动它！求源码 给高分！

Answer 1

.版本 2
.支持库 eAPI

.程序集 窗口程序集1
.程序集变量 文件路径, 文本型
.程序集变量 找到, 逻辑型

.子程序 _按钮1_被单击
.局部变量 盘符, 文本型, , "0"
.局部变量 n1, 整数型

' 程序执行流程 第一步
' 这里是判断你硬盘有几个分区的。然后一个分区一个分区去搜索，看有没有 QQ.exe
' 找到了就证明是有安装QQ，没找到就是没有安装
盘符 ＝ 取驱动器列表 ()
.计次循环首 (取数组成员数 (盘符), n1)
.如果真 (找到 ＝ 真)
跳出循环 ()
.如果真结束
文件搜索 (盘符 [n1]) ' 这里把盘符传给了 文件搜索（）子程序，要看下面 文件搜索（）那里了。看 第二步
.计次循环尾 ()
' 下面的是 第三步
' 循环结束后判断 文件路径。等于空就是没有找。不等于空就是找到了。
.判断开始 (文件路径 ≠ “”) ' 这里是判断
.如果真 (信息框 (“本电脑已安装QQ，安装路径为：” ＋ 文件路径 ＋ #换行符 ＋ “是否现在就运行QQ？！”, #是否钮 ＋ #询问图标, ) ＝ #是钮)
运行 (文件路径, 假, )
.如果真结束

.默认
信息框 (“没有安装QQ”, 0, )
.判断结束

.子程序 文件搜索
.参数 文件目录, 文本型
.局部变量 文件名, 文本型

' 这里是 第二步
' 接收到盘符以后开始搜索。
.如果真 (取文本右边 (文件目录, 1) ≠ “\”)
文件目录 ＝ 文件目录 ＋ “\”
.如果真结束
文件名 ＝ 寻找文件 (文件目录 ＋ “QQ.exe”, )
.判断循环首 (文件名 ≠ “”)
处理事件 ()
.如果真 (文件名 ＝ “QQ.exe”)
文件路径 ＝ 文件目录 ＋ 文件名 ' 如果找到QQ.exe 就把QQ的路径赋值给 文件路径。全部搜索完毕以后，上面第一个循环结束，看上面了。跳到 第三步
找到 ＝ 真
跳出循环 ()
.如果真结束
文件名 ＝ 寻找文件 (, )
.判断循环尾 ()
文件名 ＝ 寻找文件 (文件目录 ＋ “*.*”, #子目录)
.判断循环首 (文件名 ≠ “”)
.如果真 (取文本左边 (文件名, 1) ≠ “.”)
文件搜索 (文件目录 ＋ 文件名)
.如果真结束
文件名 ＝ 寻找文件 (, #子目录)
.判断循环尾 ()

Answer 2

方法是通过注册表取程序的路径，如果返回的值为零就表示没安装程序。ps:你不说什么程序我帮不了你。

追问

我是想用编辑框来输入一个程序名称。然后通过单击按钮来检测本机是否安装了我键入到编辑框的软件 谢谢

追答

那你可以搜索每个磁盘是否有那个程序的文件来达到目的，(你可以用精易模块或超级模块里面的搜索命令)