Question

vb征题--期末的程序作业

问题如下：老师要我们做一个期终的作业，是一个程序。
要求：
自选程序，程序要有实际用途，代码500-？行，其他就没必要说了....

我到底要做什么才好呢，本人程度有限，不要太难也不要太容易，数据库和网络和api 都不能用上。。。

就这些要求，我能做什么程序呢？？？？？
想了半天了.........
秋色烽火：api我会用，谢谢
依土天羽：呵呵这个不错，可是好象没什么内容把~这个会考虑的，谢谢~
lovemoe：从txt读写数据的50行还不用呢，打印的也用不到几行，用现成控件的话，不用超过50行的，自己写控件可能就能达到要求，不过有点太难了点...谢谢~~
牛A和牛C间徘徊：我不是要代码 谢谢~

Answer 1

局域网数据通讯,文件传输
几个socket控件好歹写写就要5,6百行

Answer 2

API就是复制粘贴修改

Answer 3

写个从txt文档读写数据 并能导入word,而且能实现批量打印。
从网上抄点代码一整合就ok了 什么数据库 API都不用 500行代码的话 多用点变量什么的就可以了。

Answer 4

我自己写了个200年万年历程序,也不是原创了,是把网上流行的那个网页版的万年历改写成vb的了,模块已经写好了,代码送给你吧,form1上的代码可以显示当月的数据,你可以改进下,显示任意月份的数据

500行足够了,没用api没用网络,没用数据库

1.新建工程
2.在form1上加入一个Picturebox 命名为 P
3.添加一个command1
============================
4.form1的代码
============================
Option Explicit

Private Sub Command1_Click()

Dim wStr As String
wStr = "日一二三四五六"
Dim NowX, NowY As Integer
NowX = 10
NowY = 10
Dim i As Integer
With P
.CurrentX = NowX
.CurrentY = NowY
.FontSize = 13
.FontBold = True

For i = 1 To 7
If i = 1 Then
.ForeColor = vbRed
ElseIf i = 7 Then
.ForeColor = vbGreen
Else
.ForeColor = vbBlack
End If
P.Print Mid(wStr, i, 1)
NowX = NowX + 40
.CurrentX = NowX
.CurrentY = NowY
Next
End With

Dim theWeekDay As Byte

Dim theMonthDays
theMonthDays = Array(31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31)
Dim theDays As Byte

theDays = theMonthDays(Month(Now) - 1)

Dim theRow As Byte
theRow = 0
With P
For i = 1 To theDays
.CurrentY = theRow * 40 + 30
theWeekDay = Weekday(Year(Now) & "-" & Month(Now) & "-" & i, vbMonday)
If theWeekDay > 6 Then theWeekDay = 0
NowX = theWeekDay * 40 + 5
.CurrentX = NowX

.FontSize = 12
If Day(Now) = i Then
.ForeColor = vbBlue
.FontBold = True
Else
.ForeColor = vbBlack
.FontBold = False
End If
P.Print i
.CurrentY = theRow * 40 + 30 + 20
.CurrentX = NowX
.FontSize = 9
P.Print cDay(tGetTheLunarDate(Year(Now) & "-" & Month(Now) & "-" & i).lday)
If theWeekDay + 1 = 7 Then theRow = theRow + 1: NowX = 10
Next
End With
End Sub

=================================
5.新建一个模块,输入以下代码
=================================
Option Explicit
'
'注:立春后年柱变更!
'

Public IsInit As Boolean '是否初始化

Dim lunarInfo
Dim solarMonth, Gan, Zhi, Animals, solarTerm, sTermInfo, nStr1, nStr2, monthName
Dim sFtv, wFtv, lFtv

Public Type LunarDateType
ldate As String
lyear As Integer
lmonth As Byte
lday As Byte
isLeap As Boolean
End Type

'初始化过程,写入基本信息
Function InitData()
'*****************************************************************************
' 日期资料
'*****************************************************************************

'****农历历法信息****

lunarInfo = Array(&H4BD8, &H4AE0, &HA570, &H54D5, &HD260, &HD950, &H5554, &H56AF, &H9AD0, &H55D2, _
&H4AE0, &HA5B6, &HA4D0, &HD250, &HD295, &HB54F, &HD6A0, &HADA2, &H95B0, &H4977, _
&H497F, &HA4B0, &HB4B5, &H6A50, &H6D40, &HAB54, &H2B6F, &H9570, &H52F2, &H4970, _
&H6566, &HD4A0, &HEA50, &H6A95, &H5ADF, &H2B60, &H86E3, &H92EF, &HC8D7, &HC95F, _
&HD4A0, &HD8A6, &HB55F, &H56A0, &HA5B4, &H25DF, &H92D0, &HD2B2, &HA950, &HB557, _
&H6CA0, &HB550, &H5355, &H4DAF, &HA5B0, &H4573, &H52BF, &HA9A8, &HE950, &H6AA0, _
&HAEA6, &HAB50, &H4B60, &HAAE4, &HA570, &H5260, &HF263, &HD950, &H5B57, &H56A0, _
&H96D0, &H4DD5, &H4AD0, &HA4D0, &HD4D4, &HD250, &HD558, &HB540, &HB6A0, &H95A6, _
&H95BF, &H49B0, &HA974, &HA4B0, &HB27A, &H6A50, &H6D40, &HAF46, &HAB60, &H9570, _
&H4AF5, &H4970, &H64B0, &H74A3, &HEA50, &H6B58, &H5AC0, &HAB60, &H96D5, &H92E0, _
&HC960, &HD954, &HD4A0, &HDA50, &H7552, &H56A0, &HABB7, &H25D0, &H92D0, &HCAB5, _
&HA950, &HB4A0, &HBAA4, &HAD50, &H55D9, &H4BA0, &HA5B0, &H5176, &H52BF, &HA930, _
&H7954, &H6AA0, &HAD50, &H5B52, &H4B60, &HA6E6, &HA4E0, &HD260, &HEA65, &HD530, _
&H5AA0, &H76A3, &H96D0, &H4AFB, &H4AD0, &HA4D0, &HD0B6, &HD25F, &HD520, &HDD45, _
&HB5A0, &H56D0, &H55B2, &H49B0, &HA577, &HA4B0, &HAA50, &HB255, &H6D2F, &HADA0, _
&H4B63, &H937F, &H49F8, &H4970, &H64B0, &H68A6, &HEA5F, &H6B20, &HA6C4, &HAAEF, _
&H92E0, &HD2E3, &HC960, &HD557, &HD4A0, &HDA50, &H5D55, &H56A0, &HA6D0, &H55D4, _
&H52D0, &HA9B8, &HA950, &HB4A0, &HB6A6, &HAD50, &H55A0, &HABA4, &HA5B0, &H52B0, _
&HB273, &H6930, &H7337, &H6AA0, &HAD50, &H4B55, &H4B6F, &HA570, &H54E4, &HD260, _
&HE968, &HD520, &HDAA0, &H6AA6, &H56DF, &H4AE0, &HA9D4, &HA4D0, &HD150, &HF252, _
&HD520, &HD520)

'阳历月份日期信息
solarMonth = Array(31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31)
'天干
Gan = Array("甲", "乙", "丙", "丁", "戊", "己", "庚", "辛", "壬", "癸")
'地支
Zhi = Array("子", "丑", "寅", "卯", "辰", "巳", "午", "未", "申", "酉", "戌", "亥")
'生肖
Animals = Array("鼠", "牛", "虎", "兔", "龙", "蛇", "马", "羊", "猴", "鸡", "狗", "猪")
'节气名称
solarTerm = Array("小寒", "大寒", "立春", "雨水", "惊蛰", "春分", "清明", "谷雨", "立夏", "小满", "芒种", "夏至", "小暑", "大暑", "立秋", "处暑", "白露", "秋分", "寒露", "霜降", "立冬", "小雪", "大雪", "冬至")
'节气信息
sTermInfo = Array(0, 21208, 42467, 63836, 85337, 107014, 128867, 150921, 173149, 195551, 218072, 240693, 263343, 285989, 308563, 331033, 353350, 375494, 397447, 419210, 440795, 462224, 483532, 504758)
'农历月份日期名称
nStr1 = Array("日", "一", "二", "三", "四", "五", "六", "七", "八", "九", "十")
nStr2 = Array("初", "十", "廿", "卅", "□")
'月份英文名 :)
monthName = Array("JAN", "FEB", "MAR", "APR", "MAY", "JUN", "JUL", "AUG", "SEP", "OCT", "NOV", "DEC")

'公历节日 *表示放假日
sFtv = Array( _
"0101*新年元旦", _
"0202 世界湿地日", "0207 国际声援南非日", "0210 国际气象节", "0214 情人节", _
"0301 国际海豹日", "0303 全国爱耳日", "0308 国际妇女节", "0312 植树节 孙中山逝世纪念日", "0314 国际警察日", "0315 国际消费者权益日", "0317 中国国医节||国际航海日", "0321 世界森林日||消除种族歧视国际日", "0321 世界儿歌日", "0322 世界水日", "0323 世界气象日", "0324 世界防治结核病日", "0325 全国中小学生安全教育日", "0330 巴勒斯坦国土日", _
"0401 愚人节||全国爱国卫生运动月(四月)||税收宣传月(四月)", "0407 世界卫生日", "0422 世界地球日", "0423 世界图书和版权日", "0424 亚非新闻工作者日", _
"0501 国际劳动节", "0504 中国五四青年节", "0505 碘缺乏病防治日", "0508 世界红十字日", "0512 国际护士节", "0515 国际家庭日", "0517 世界电信日", "0518 国际博物馆日", "0520 全国学生营养日", "0523 国际牛奶日", "0531 世界无烟日", _
"0601 国际儿童节", "0605 世界环境日", "0606 全国爱眼日", "0617 防治荒漠化和干旱日", "0623 国际奥林匹克日", "0625 全国土地日", "0626 国际反毒品日", _
"0701 中国共产党建党日 世界建筑日", "0702 国际体育记者日", "0707 中国人民抗日战争纪念日", "0711 世界人口日", "0730 非洲妇女日", _
"0801 中国建军节", "0808 中国男子节(爸爸节)", "0815 日本正式宣布无条件投降日", _
"0908 国际扫盲日 国际新闻工作者日", "0910 教师节", _
"0914 世界清洁地球日", "0916 国际臭氧层保护日", "0918 九·一八事变纪念日", "0920 国际爱牙日", "0927 世界旅游日", _
"1001*国庆节||世界音乐日||国际老人节", "1001 国际音乐日", "1002 国际和平与民主自由斗争日", "1004 世界动物日", "1008 全国高血压日", "1008 世界视觉日", "1009 世界邮政日 万国邮联日", "1010 辛亥革命纪念日 世界精神卫生日", "1013 世界保健日 国际教师节", "1014 世界标准日", "1015 国际盲人节(白手杖节)", "1016 世界粮食日", "1017 世界消除贫困日", "1022 世界传统医药日", "1024 联合国日||世界发展信息日", "1031 世界勤俭日", _
"1107 十月社会主义革命纪念日", "1108 中国记者日", "1109 全国消防安全宣传教育日", "1110 世界青年节", "1111 国际科学与和平周(本日所属的一周)", "1112 孙中山诞辰纪念日", "1114 世界糖尿病日", "1117 国际大学生节||世界学生节", "1121 世界问候日||世界电视日", "1129 国际声援巴勒斯坦人民国际日", _
"1201 世界艾滋病日", "1203 世界残疾人日", "1205 国际经济和社会发展志愿人员日", "1208 国际儿童电视日", "1209 世界足球日", "1210 世界人权日", "1212 西安事变纪念日", "1213 南京大屠杀(1937年)纪念日", "1221 国际篮球日", "1224 平安夜", "1225 圣诞节", _
"1229 国际生物多样性日")

'某月的第几个星期几。 5,6,7,8 表示到数第 1,2,3,4 个星期几
wFtv = Array( _
"0110 黑人日", _
"0150 世界麻风日", _
"0520 国际母亲节", _
"0530 全国助残日", _
"0630 父亲节", _
"0911 劳动节", _
"0932 国际和平日", _
"0940 国际聋人节 世界儿童日", _
"0950 世界海事日", _
"1011 国际住房日", _
"1013 国际减轻自然灾害日(减灾日)", _
"1144 感恩节")

'农历节日
lFtv = Array( _
"0101*春节", _
"0115 元宵节", _
"0202 龙抬头节", _
"0323 妈祖生辰 (天上圣母诞辰)", _
"0505 端午节", _
"0613 雪影男孩的生日", _
"0707 七七中国情人节", _
"0815 中秋节", _
"0909 重阳节", _
"1208 腊八节", _
"1223 灶君(祭灶)节", _
"0100*除夕")

IsInit = True
End Function

'*****************************************************************************
' 可供调用函数
'*****************************************************************************

'******* 输入阳历年,返回干支年
'
'参数 日期 / 新年是否从立春算起(为True则新年从立春算)
'
Public Function tGetTheGZYear(ByVal theDate As Date, Optional ByVal LiChun As Boolean = False)

If Not IsInit Then InitData '初始化

'年柱 1900年立春后为庚子年(60进制36)
If LiChun Then
If Month(theDate) - 1 < 2 Then
tGetTheGZYear = tCyclical(Year(theDate) - 1900 + 36 - 1)
Else
tGetTheGZYear = tCyclical(Year(theDate) - 1900 + 36)
End If
Else
tGetTheGZYear = tCyclical(Year(theDate) - 1900 + 36)
End If
End Function

'****************************************************
'函数名 tGetTheLunarDate
'参数 合法日期
'功能 根据阳历返回农历信息,本函数返回类型为LunarDateType

'ldate 完整日期
'lyear 农历年
'lmonth 月
'lday 日
'isLeap As Boolean 是否闰月

'***************************************************
Public Function tGetTheLunarDate(ByVal theDate As Date) As LunarDateType

If Not IsDate(theDate) Then Exit Function '检测日期

Dim i, leap, temp, offset

If Not IsInit Then InitData '初始化

leap = 0
temp = 0
offset = DateDiff("d", "1900-1-31", theDate)

For i = 1900 To 2100 - 1
If offset <= 0 Then Exit For
temp = lYearDays(i)
offset = offset - temp
Next

If offset < 0 Then offset = offset + temp: i = i - 1

tGetTheLunarDate.lyear = i
leap = leapMonth(i) ' //闰哪个月
tGetTheLunarDate.isLeap = False

For i = 1 To 12
If offset <= 0 Then Exit For
' 闰月
If leap > 0 And i = (leap + 1) And tGetTheLunarDate.isLeap = False Then
i = i - 1
tGetTheLunarDate.isLeap = True
temp = leapDays(tGetTheLunarDate.lyear)
Else
temp = monthDays(tGetTheLunarDate.lyear, i)
End If

' 解除闰月
If tGetTheLunarDate.isLeap = True And i = (leap + 1) Then tGetTheLunarDate.isLeap = False

offset = offset - temp
Next

If offset = 0 And leap > 0 And i = leap + 1 Then
If tGetTheLunarDate.isLeap Then
tGetTheLunarDate.isLeap = False
Else
tGetTheLunarDate.isLeap = True
i = i - 1
End If
End If

If offset < 0 Then offset = offset + temp: i = i - 1

tGetTheLunarDate.lmonth = i
tGetTheLunarDate.lday = offset + 1
tGetTheLunarDate.ldate = tGetTheLunarDate.lyear & "-" & tGetTheLunarDate.lmonth & "-" & tGetTheLunarDate.lday
End Function

'************************根据年份取得生肖
'参数 年份
Function tGetTheAnimal(ByVal theYear As Integer)
If theYear > 2100 Or theYear < 1900 Then Exit Function

If Not IsInit Then InitData '初始化

tGetTheAnimal = Animals((theYear - 4) Mod 12)
End Function

'*****************************************************************************
' 日期计算
'*****************************************************************************
'
''====================================== 返回农历 y年的总天数
Function lYearDays(y)

If Not IsInit Then InitData '初始化

Dim i As Long, sum As Integer
i = 32768
sum = 348
Do While i > 8
sum = sum + IIf(lunarInfo(y - 1900) And i, 1, 0)
i = i / 2
Loop
lYearDays = sum + leapDays(y)
End Function

'====================================== 返回农历 y年闰月的天数
Function leapDays(y)

If Not IsInit Then InitData '初始化

If leapMonth(y) <> 0 Then
leapDays = IIf((lunarInfo(y - 1899) And &HF) = &HF, 30, 29)
Else
leapDays = 0
End If
End Function

'====================================== 返回农历 y年闰哪个月 1-12 , 没闰返回 0
Function leapMonth(y)

If Not IsInit Then InitData '初始化

Dim lm
lm = lunarInfo(y - 1900) And 15
leapMonth = IIf(lm = 15, 0, lm)
End Function

'====================================== 返回农历 y年m月的总天数
Function monthDays(y, m)

If Not IsInit Then InitData '初始化

monthDays = IIf(lunarInfo(y - 1900) And (65536 / 2 ^ m), 30, 29)
End Function

'============================== 传入 offset 返回干支, 0=甲子
Function tCyclical(num)
tCyclical = Gan(num Mod 10) + Zhi(num Mod 12)
End Function

'中文日期
Function cDay(d)
Dim s
Select Case d
Case 10
s = "初十"
Case 20
s = "二十"
Case 30
s = "三十"
Case Else
s = nStr2(Int(d / 10))
s = s & nStr1(d Mod 10)
End Select
cDay = s
End Function