Question

bat文件中程序返回码在if语句嵌套下的返回值问题,求解！！

本机当前IP为192.168.1.254，目的是想通过IP来判断当前网段以便做其它操作。现在遇到%errorlevel%在if嵌套下的返回值不能改变，也就是继承第一个find时的值，为什么？当如何修改?
@echo off
@ipconfig >ip.txt
@find "192.168.2" ip.txt >nul
if %errorlevel%==1 (
@find "192.168.1" ip.txt >nul
if %errorlevel%==1 (
echo 当前为未知网段设置!!!
) else (
echo 当前为1网段设置!!!
)
) else (
echo 当前为2网段设置!!!
)

Answer 1

@echo off
setlocal enabledelayedexpansion
@ipconfig >ip.txt
@find "192.168.2" ip.txt >nul
if %errorlevel%==1 (
  @find "192.168.1." ip.txt >nul
  if !errorlevel!==1  (
    echo       当前为未知网段设置!!!
    ) else (
        echo      当前为1网段设置!!!
            )
   ) else (
    echo      当前为2网段设置!!!
)
pause

可以 启用延迟变量扩展.

或者

@echo off
@ipconfig >ip.txt
@find "192.168.2." ip.txt >nul
if errorlevel==1 (
  @find "192.168.1." ip.txt >nul
  if errorlevel==1  (
    echo       当前为未知网段设置!!!
    ) else (
        echo      当前为1网段设置!!!
            )
   ) else (
    echo      当前为2网段设置!!!
)
pause

可以将"192.168.2"改为"192.168.2."

"192.168.1"改为"192.168.1."

Answer 2

@echo off
ipconfig >ip.txt
find "192.168.2" ip.txt >nul && echo 当前为2网段!!! || find "192.168.1" ip.txt >nul && echo 当前为1网段!!! || echo 当前为未知网段设置!!!
pause