Question

批处理合并多个文本内容

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%i in (1.txt)do (set /a a+=1,b=0
for /f "delims=" %%j in (2.txt)do (set /a b+=1
if !a!==!b! echo %%i%%j>>wind.txt))
：：这代码是合并两个文本内容的，在网看到很多，就这个比较精简。结果为1文本的内容每行后面接就是2文本的内容，这也是我想要的结果，但我不懂得如果两个以上的文本如何修改这代码。想要的结果如：有二个以文本，第一个后面紧接着第二个，后面双紧接着第三个，中间不要空格，以此类推。求批处理高手！！
求高手帮修改，或者有其它精简的代码！

Answer 1

@echo off & setlocal enabledelayedexpansion
set "file=1.txt 2.txt 3.txt"
set /a filenum=3
rem 在这里修改，文件名称之间用空格隔开，filenum是文件个数（注意文本文档的名称中间不能有空格）
(for /l %%n in (1 1 %filenum%) do (
set /a n+=1
for %%a in (%file%) do (
for /f "tokens=* delims=" %%i in (%%a) do (
set /a line+=1
if !line! equ !n! set /p=%%i<nul)
set /a line=0)
echo.))>result.txt
pause

额。这样修改下不用无限嵌套了

追问

这个代码只是执行每个文件的前面三行而以，没有完全。

追答

@echo off & setlocal enabledelayedexpansion
set "file=1.txt 2.txt 3.txt"
:cl
set /a n+=1 & set "linestr="
for %%a in (%file%) do (
for /f "tokens=* delims=" %%i in (%%a) do (
set /a line+=1
if !line! equ !n! set "linestr=!linestr!%%i")
set /a line=0)
if not "!linestr!"=="" echo !linestr!>>result.txt & goto cl

测试通过，刚才抱歉。。= =~

Answer 2

如果每个文件行数一样的话比较好办，不一样就复杂一些。
先写个一样的。
1、处理当前目录所有txt
@echo off
setlocal enabledelayedexpansion
for /f %%i in ('dir/b/on *.txt') do (
set/a n+=1
set m=
for /f "tokens=*" %%j in ('type "%%i"') do (
set/a m+=1
set #!n!!m!=%%j))
(for /l %%i in (1,1,%m%) do (
for /l %%j in (1,1,%n%) do (
call echo !#%%j%%i!)))>a.out
start a.out
2、处理指定txt
@echo off
setlocal enabledelayedexpansion
set f=a.txt b.txt c.txt
for %%i in (%f%) do (
set/a n+=1
set m=
for /f "tokens=*" %%j in ('type "%%i"') do (
set/a m+=1
set #!n!!m!=%%j))
(for /l %%i in (1,1,%m%) do (
for /l %%j in (1,1,%n%) do (
call set/p a=!#%%j%%i!<nul)
echo.
))>a.out

Answer 3

我不知道用这个命令 type *.*>>a.txt 可不可以解决你的问题. 我一般都是这么合并CSV档案的.