Question

易语言 关于多个编辑框间运行四则运算以及将计算过程生成到一编辑框中的问题

像图片中显示，我需要的效果是：在编辑框8中 显示整个计算过程，如果编辑框1到编辑框6中存在空值，那么编辑框8中自动将空的剔除。例如：编辑框1.内容=2，编辑框2.内容=3，编辑框3.内容=5，编辑框4.内容=3，而编辑框5和编辑框6为空，那么单击按钮1后，编辑框8中就显示 2×3+5×3=21，编辑框7种显示21
这里前6个编辑框只是是例子，实际上有很多编辑框，具体哪个为空也不一定，需要判断非空的才在编辑框8中显示

Answer 1

.版本 2

.程序集 窗口程序集1

.子程序 _按钮1_被单击

.判断开始 (编辑框1.内容 ≠ “” 且 编辑框2.内容 ≠ “” 且 编辑框3.内容 ≠ “” 且 编辑框4.内容 ≠ “” 且 编辑框5.内容 ≠ “” 且 编辑框6.内容 ≠ “”)

    编辑框7.内容 ＝ 到文本 (到数值 (编辑框1.内容) × 到数值 (编辑框2.内容) ＋ 到数值 (编辑框3.内容) × 到数值 (编辑框4.内容) ＋ 到数值 (编辑框6.内容) × 到数值 (编辑框6.内容))

    编辑框8.内容 ＝ 编辑框1.内容 ＋ “×” ＋ 编辑框2.内容 ＋ “+” ＋ 编辑框3.内容 ＋ “×” ＋ 编辑框4.内容 ＋ “+” ＋ 编辑框5.内容 ＋ “×” ＋ 编辑框6.内容 ＋ “=” ＋ 编辑框7.内容

.默认

    编辑框8.内容 ＝ “”

.判断结束

追问

我的意思是 如果有个别编辑框为空时，计算过程这里 就自动不把为空的编辑框列入计算过程
按你的这个代码 所有的编辑框都必须有数据，否则 编辑框8就不显示计算过程，我要的结果是
假如 编辑框5、编辑框6为空时 ，编辑框8里只显示 前4个编辑框的数据内容
按你的数据，只显示11×12+12×545=6672
而且 这里的6个编辑框也只是 举例图 实际我要的有40个编辑框，运算时 不一定哪个编辑框为空

追答

那样就要做很久了 我试一下

Answer 2

如果你的编辑框1，编辑框3 为空你的等式又是怎样的？ 是下面的样式么？

追问

为空的编辑框 值就是0 在过程中就不显示
第二个是 8×9+1×3=75
第三个是1×3=3

追答

直接套用公式

到整数（编辑框1.内容）*到整数（编辑框2.内容）+到整数（编辑框3.内容）*到整数（编辑框4.内容）+到整数（编辑框5.内容）*到整数（编辑框6.内容）

编辑框为空，到整数=0，四则运算，乘0=0

Answer 3

.版本 2
.支持库 script
.局部变量 NN, 整数型
.局部变量 算式文本, 文本型
.局部变量 标记编辑框, 编辑框
.局部变量 标记标签, 标签
算式文本 ＝ 编辑框1.内容
.变量循环首 (3, 11, 2, NN)
标记编辑框 ＝ 取标记组件 (NN)
标记标签 ＝ 取标记组件 (NN － 1)
.如果真 (标记编辑框.内容 ＝ “”)
到循环尾 ()
.如果真结束
.如果 (算式文本 ＝ “”)
算式文本 ＝ 标记编辑框.内容
.否则
算式文本 ＝ 算式文本 ＋ 标记标签.标题 ＋ 标记编辑框.内容
.如果结束
.变量循环尾 ()
.如果 (算式文本 ＝ “”)
编辑框7.内容 ＝ “”
.否则
编辑框7.内容 ＝ 算式文本 ＋ “＝”
算式文本 ＝ 子文本替换 (算式文本, “×”, “*”, , , 真)
算式文本 ＝ 子文本替换 (算式文本, “＋”, “+”, , , 真)
编辑框7.加入文本 (脚本组件1.计算表达式 (算式文本))
.如果结束

本例省去了等号后面的编辑框，所以只有7个。对6个编辑框与5个标签设置标记从1到11，使用脚本组件进行计算。这几乎是标准答案了。

追问

你这里面的 脚本组件1 是什么模块？ 没有这个无法运行

追答

脚本组件是脚本支持库里的，你配置支持库就可以找到，添加到窗口上就可以了。

追问

有错误

追答

编辑框1—编辑框6的标记分别为：1、3、5、7、9、11
标签1—标签5的标记分别为：2、4、6、8、10
标记在组件的属性面板里设置。

追问

基本问题已经解决了 现在还一个问题就是两数相乘 当有一个为空时（为空 程序认为是0）这时，我要求计算过程中对有一个为空的数据 不进行计算，你的这个代码还是计算了

也就是如图所示

 图中对于编辑框4位空了 进行了 加法计算 我要求它就是出现1×2=2 而不是1×2+3=5这种

还请再改下吧

追答

如果那样的话，只需要再加判断就行，检查成对的编辑框是否有内容。并且你问题中并没有说有一个为空就不计算啊。
给你重做了一下，实现了你要的功能。
标签的标记不再使用，编辑框的标记按顺序为1、2、3、4、5、6，代码如下：

.版本 2
.支持库 script
.子程序 _按钮2_被单击
连续赋值 (“”, 编辑框1.内容, 编辑框2.内容, 编辑框3.内容, 编辑框4.内容, 编辑框5.内容, 编辑框6.内容, 编辑框7.内容)
.子程序 _按钮1_被单击
.局部变量 NN, 整数型
.局部变量 算式文本, 文本型
.局部变量 标记编辑框, 编辑框
.局部变量 标记编辑框2, 编辑框
算式文本 ＝ “”
.变量循环首 (1, 6, 2, NN)
标记编辑框 ＝ 取标记组件 (NN)
标记编辑框2 ＝ 取标记组件 (NN ＋ 1)
.如果真 (标记编辑框.内容 ＝ “” 或 标记编辑框2.内容 ＝ “”)
到循环尾 ()
.如果真结束
.如果 (算式文本 ＝ “”)
算式文本 ＝ 标记编辑框.内容 ＋ “×” ＋ 标记编辑框2.内容
.否则
算式文本 ＝ 算式文本 ＋ “＋” ＋ 标记编辑框.内容 ＋ “×” ＋ 标记编辑框2.内容
.如果结束
.变量循环尾 ()
.如果 (算式文本 ＝ “”)
编辑框7.内容 ＝ “”
.否则
编辑框7.内容 ＝ 算式文本 ＋ “＝”
算式文本 ＝ 子文本替换 (算式文本, “×”, “*”, , , 真)
算式文本 ＝ 子文本替换 (算式文本, “＋”, “+”, , , 真)
编辑框7.加入文本 (脚本组件1.计算表达式 (算式文本))
.如果结束

可以采纳了，此为最佳答案^_^

Answer 4

图片中显示，我需要的效果是：在编辑框8中 显示整个计算过程，如果编辑框1到编辑框6中存在空值，那么编辑框8中自动将空的剔除。例如：编辑框1.内容=2，编辑框2.内容=3，编辑框3.内容=5，编辑框4.内容=3，而编辑框5和编辑框6为空，那么单击按钮1后，编辑框8中就显示 2×3+5×3=21，编辑框7种显示21
这里前6个编辑框只是是例子，实际上有很多编辑框，具体哪个为空也不一定，需要判断非空的才在编辑框8中显示