Question

易语言写配置项和读配置项的具体做法

比如我要记录启动窗口的左边和顶边，怎么在我改动的时候写配置项然后在关闭的时候保存，然后下次登录的时候载入大小，好的再加50分，摆脱了，真心求教

Answer 1

.版本 2
.子程序 读用户配置
' 配置文件名, "“\USERSYS.ini”", , 用户配置文件
' 系统风格节, "“系统风格”", , 系统配置XP风格
' 风格, "“XP风格”", , 界面使用XP风格样式
' 窗口位置左, "“左边”"
' 窗口位置顶, "“顶边”"
' 窗口宽, "“宽度”"
' 窗口高, "“高度”"
' 用户配色节, "“自定义颜色”", , 用户自定义的配置
' 窗口色项, "“窗口背景”"
' 编辑框底色, "“文字背景”"
' 文字色项, "“文字颜色”"
' 文字大小, "“字号”"
' 文字字体, "“字体”"
' 用户信息节, "“用户信息”", , 用户的信息
' 名项, "“用户名”"
' 址项, "“用户公司”"
' 最近文件节, "“最近打开”", , 使用的文件
' 上次文件, "“上次打开”"
' 自动打开, "“自动打开”"
上次文件.标题 ＝ “”
.如果 (读配置项 (配置路径, #最近文件节, #自动打开, ) ＝ “YES”)
自动打开.选中 ＝ 真
.如果真 (文件是否存在 (读配置项 (配置路径, #最近文件节, #上次文件, )))
上次文件.标题 ＝ 读配置项 (配置路径, #最近文件节, #上次文件, )
上次文件.可视 ＝ 上次文件.标题 ≠ “”
_上次文件_被选择 ()
.如果真结束
.否则
自动打开.选中 ＝ 假
上次文件.可视 ＝ 假
.如果结束
.如果 (读配置项 (配置路径, #系统风格节, #最大化, ) ≠ “YES”)
_启动窗口.移动 (到数值 (读配置项 (配置路径, #系统风格节, #窗口位置左, )), 到数值 (读配置项 (配置路径, #系统风格节, #窗口位置顶, )), 到数值 (读配置项 (配置路径, #系统风格节, #窗口宽, “400”)), 到数值 (读配置项 (配置路径, #系统风格节, #窗口高, “300”)))
.否则
_启动窗口.位置 ＝ 3
.如果结束
总是最前.选中 ＝ 读配置项 (配置路径, #系统风格节, #总在最前, ) ＝ “1”
_启动窗口.总在最前 ＝ 总是最前.选中
编辑框1.字体.字体大小 ＝ 到数值 (读配置项 (配置路径, #用户配色节, #文字大小, “9”))
编辑框1.字体.字体名称 ＝ 读配置项 (配置路径, #用户配色节, #文字字体, “宋体”)
读配色 ()
读用户 ()
读风格 ()

.版本 2
.子程序 读配色
_启动窗口.底色 ＝ 到数值 (读配置项 (配置路径, #用户配色节, #窗口色项, 到文本 (#默认色)))
编辑框1.背景颜色 ＝ 到数值 (读配置项 (配置路径, #用户配色节, #编辑框底色, 到文本 (#白色)))
编辑框1.文本颜色 ＝ 到数值 (读配置项 (配置路径, #用户配色节, #文字色项, 到文本 (#黑色)))

.版本 2
.支持库 xplib
.子程序 读风格
.局部变量 KK, 整数型
连续赋值 (假, 无风格.禁止, 蓝色风格.禁止, 绿色风格.禁止, 银色风格.禁止)
KK ＝ 到数值 (读配置项 (配置路径, #系统风格节, #风格, “0”))
XP风格 (KK)
.判断开始 (KK ＝ 0)
无风格.禁止 ＝ 真
.判断 (KK ＝ 1)
蓝色风格.禁止 ＝ 真
.判断 (KK ＝ 2)
绿色风格.禁止 ＝ 真
.判断 (KK ＝ 3)
银色风格.禁止 ＝ 真
.默认
.判断结束

.版本 2
.子程序 读用户
_启动窗口.标题 ＝ 读配置项 (配置路径, #用户信息节, #名项, “大强”) ＋ “记事本”

.版本 2
.子程序 __启动窗口_尺寸被改变
.如果真 (_启动窗口.宽度 ≤ 200)

_启动窗口.宽度 ＝ 200
.如果真结束
.如果真 (_启动窗口.高度 ≤ 300)
_启动窗口.高度 ＝ 300
.如果真结束
.如果真 (_启动窗口.位置 ≠ 3)
写配置项 (配置路径, #系统风格节, #窗口位置左, 到文本 (_启动窗口.左边))
写配置项 (配置路径, #系统风格节, #窗口位置顶, 到文本 (_启动窗口.顶边))
写配置项 (配置路径, #系统风格节, #窗口宽, 到文本 (_启动窗口.宽度))
写配置项 (配置路径, #系统风格节, #窗口高, 到文本 (_启动窗口.高度))
_启动窗口.移动 (到数值 (读配置项 (配置路径, #系统风格节, #窗口位置左, )), 到数值 (读配置项 (配置路径, #系统风格节, #窗口位置顶, )), 到数值 (读配置项 (配置路径, #系统风格节, #窗口宽, “400”)), 到数值 (读配置项 (配置路径, #系统风格节, #窗口高, “300”)))
.如果真结束
编辑框1.移动 (5, 5, _启动窗口.取用户区宽度 () － 10, _启动窗口.取用户区高度 () － 10)

这是我的程序中的代码，你也可以到易语言资源网去下载这个程序的源码。

Answer 2

.版本 2
.程序集 窗口程序集1
.子程序 __启动窗口_创建完毕
.如果 (文件是否存在 (取运行目录 () ＋ “\e.ini”))
' 读入INI窗口数据并改变窗体位置大小
_启动窗口.左边 ＝ 到整数 (读配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Left”, ))
_启动窗口.顶边 ＝ 到整数 (读配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Top”, ))
_启动窗口.宽度 ＝ 到整数 (读配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Winth”, ))
_启动窗口.高度 ＝ 到整数 (读配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “High”, ))
.否则
' 初始创建INI窗口坐标数据
写配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Left”, 到文本 (_启动窗口.左边))
写配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Top”, 到文本 (_启动窗口.顶边))
写配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Winth”, 到文本 (_启动窗口.宽度))
写配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “High”, 到文本 (_启动窗口.高度))
.如果结束

.子程序 __启动窗口_尺寸被改变
' 改变尺寸时写入INI
写配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Left”, 到文本 (_启动窗口.左边))
写配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Top”, 到文本 (_启动窗口.顶边))
写配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “Winth”, 到文本 (_启动窗口.宽度))
写配置项 (取运行目录 () ＋ “\e.ini”, “Wind”, “High”, 到文本 (_启动窗口.高度))

'也可加在窗体关闭时写入。。

追问

嗯。。。能说明一下Wind”, “High这写文字是干什么的吗？

追答

自己设定的INI文件里的节名称和配置项名称啊。。

以上代码得出的INI文件内容：

[Wind]
Left=530
Top=325
Winth=380
High=250

追问

那个。。。最后一个问题，可能有些跑了，怎么得出

任务栏的高度，我要设置最大化，需要用到这个，_启动窗口位置和发送信息最大化都是直接覆盖任务栏了，摆脱啦，这个任务20分

追答

帮人帮到底，，直接给你个完整的实例吧：

.版本 2

.子程序 _按钮1_被单击
.局部变量 Ren, RECT
.局部变量 宽, 整数型
.局部变量 高, 整数型
.局部变量 位置, 文本型

宽 ＝ 取屏幕宽度 ()高 ＝ 取屏幕高度 ()
GetWindowRect (FindWindowA (“Shell_TrayWnd”, “”), Ren)
.如果真 (Ren.ToP ＝ 0 且 Ren.Left ＝ 0 且 Ren.Right ＜ Ren.Bottom) ' 任务栏在左边
位置 ＝ “左边”
宽 ＝ 宽 ＋ Ren.Right
.如果真结束

.如果真 (Ren.ToP ＝ 0 且 Ren.Left ＝ 0 且 Ren.Right ＞ Ren.Bottom) ' 任务栏在顶部
位置 ＝ “上边”
高 ＝ 高 ＋ Ren.Bottom
.如果真结束

.如果真 (Ren.ToP ≠ 0 且 Ren.Left ＝ 0) ' 任务栏在下面
位置 ＝ “下边”
高 ＝ 高 － (Ren.Bottom － Ren.ToP)
.如果真结束

.如果真 (Ren.ToP ＝ 0 且 Ren.Left ≠ 0) ' 任务栏在右边
位置 ＝ “右边”
宽 ＝ 宽 － (Ren.Right － Ren.Left)
.如果真结束

信息框 (“任务栏在” ＋ 位置 ＋ “，去除任务栏后的大小为：” ＋ 到文本 (宽) ＋ “ X ” ＋ 到文本 (高) ＋ “,任务栏高度：” ＋ 到文本 (Ren.Bottom － Ren.ToP), 0, )

Answer 3

写配置项 (取运行目录 () ＋ “\” ＋ “cipher.ini”, “user”, “账号”, 编辑框1.内容)
写配置项 (取运行目录 () ＋ “\” ＋ “cipher.ini”, “user”, “密码”, 编辑框2.内容)
例子，可随意改动...

Answer 4

784686反对个人的个人投入大概