Question

SQL问题：本想执行update修改一条数据的，结果忘记写where条件了。结果那个表的那一列都改了。能改回来么

PS:我通说一不小心用delete的用一个软件能找回来。是什么。

Answer 1

修改之前没进行备份数据？ 可怜的娃。。。
方法一：
数据还原到指定时间点的处理示例:
--创建测试数据库
CREATE DATABASE Db
GO
--对数据库进行备份
BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT
GO
--创建测试表
CREATE TABLE Db.dbo.TB_test(ID int)
--延时1秒钟,再进行后面的操作(这是由于SQL Server的时间精度最大为百分之三秒,不延时的话,可能会导致还原到时间点的操作失败)
WAITFOR DELAY '00:00:01'
GO
--假设我们现在误操作删除了 Db.dbo.TB_test 这个表
DROP TABLE Db.dbo.TB_test
--保存删除表的时间
SELECT dt=GETDATE() INTO #
GO
--在删除操作后,发现不应该删除表 Db.dbo.TB_test
--下面演示了如何恢复这个误删除的表 Db.dbo.TB_test
--首先,备份事务日志(使用事务日志才能还原到指定的时间点)
BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT
GO
--接下来,我们要先还原完全备份(还原日志必须在还原完全备份的基础上进行)
RESTORE DATABASE Db FROM DISK='c:\db.bak' WITH REPLACE,NORECOVERY
GO
--将事务日志还原到删除操作前（这里的时间对应上面的删除时间，并比删除时间略早
DECLARE @dt datetime
SELECT @dt=DATEADD(ms,-20,dt) FROM # --获取比表被删除的时间略早的时间
RESTORE LOG Db FROM DISK='c:\db_log.bak' WITH RECOVERY,STOPAT=@dt
GO
--查询一下,看表是否恢复
SELECT * FROM Db.dbo.TB_test
/*--结果:
ID
-----------
（所影响的行数为 0 行）
--*/
--测试成功
GO
--最后删除我们做的测试环境
DROP DATABASE Db
DROP TABLE #

方法二：
用日志工具Log Explorer
步骤：
1、查看日志
a、打开log explorer，选择菜单File--> attach log file
b、在Log File Selection窗口中，填写连接到要恢复数据的数据库服务器机器名、数据库登录ID及密码，然后点击 "Connect "按钮。
c、若连接成功，则窗口左边树将显示命令菜单，这时我们点击Browser下的View Log命令，此时窗口右边则出现该数据库的Log。
2、恢复数据库
这时您只要选择您要恢复对事件点，右键点击选择 "undo transation "命令，保存T-SQL代码，然后在查询分析器中执行该T-SQL代码

Answer 2

这个基本不可能，直接修改以后，已经把磁盘数据重新写了一边。而那种所谓的文件找回来，是因为，文件只是删掉了，文件名分配表。而文件内容本身并没有删掉。