Question

如何用易语言正则取以下值？

图片红框里的两个参数

感激不尽！

Answer 1

表达式：<td>(.*?)</td>  可以取<td>标签里面的所有内容 如果只是要里面的IP和端口

表达式：<td>([0-9.]*)</td>  下方代码中 创建 (“<td>([0-9.]*)</td>”) 引号为表达式

精益模块：

.版本 2

.子程序 正则_匹配批量, 整数型, , 成功返回匹配的数量，失败返回0。
.参数 源文本, 文本型, , 欲被匹配的文本
.局部变量 局_正则, 正则表达式类, , , 
.局部变量 局_匹配数, 整数型
.局部变量 局_计次, 整数型

.如果真 (局_正则.创建 (“<td>([0-9.]*)</td>”, 源文本, 假, 假, 真) ＝ 假)
    信息框 (“正则创建失败，请检查正则表达式语句是否有误！”, #错误图标, )
    返回 (0)
.如果真结束
局_匹配数 ＝ 局_正则.取匹配数量 ()
.如果真 (局_匹配数 ＝ 0)
    信息框 (“匹配失败，请检检查正则语句是否有误，数量：0”, #错误图标, )
    返回 (0)
.如果真结束
.计次循环首 (局_匹配数, 局_计次)
    输出调试文本 (“匹配文本 ” ＋ 到文本 (局_计次) ＋ “ 中的子匹配文本 1：” ＋ 局_正则.取子匹配文本 (局_计次, 1))
.计次循环尾 ()
返回 (局_匹配数)

核心支持库：

.版本 2
.支持库 RegEx

.子程序 正则_匹配批量, 整数型, , 成功返回匹配的数量，失败返回0。
.参数 源文本, 文本型, , 欲被匹配的文本
.局部变量 局_正则, 正则表达式, , , 
.局部变量 局_搜索结果, 搜索结果, 静态, "0"
.局部变量 局_匹配数, 整数型, , , 匹配数量
.局部变量 局_计次, 整数型

.如果真 (局_正则.创建 (“<td>([0-9.]*)</td>”, 假) ＝ 假)
    信息框 (“正则创建失败，请检查正则表达式语句是否有误！”, #错误图标, )
    返回 (0)
.如果真结束
局_正则.多行模式 ＝ 假
局_搜索结果 ＝ 局_正则.搜索全部 (源文本)
局_匹配数 ＝ 取数组成员数 (局_搜索结果)
.如果真 (局_匹配数 ＝ 0)
    信息框 (“匹配失败，请检检查正则语句是否有误，数量：0”, #错误图标, )
    返回 (0)
.如果真结束
.计次循环首 (局_匹配数, 局_计次)
    输出调试文本 (“匹配文本 ” ＋ 到文本 (局_计次) ＋ “ 中的子匹配文本 1：” ＋ 局_搜索结果 [局_计次].取子匹配文本 (源文本, 1, ))
.计次循环尾 ()
返回 (局_匹配数)