Question

请教，VBS脚本怎么获取电脑硬件序列号？

大家好，我想用VBS获取电脑的硬件序列号，请教一个实例。
最好有：
CPU序列号
硬盘序列号
主板序列号

然后输出文本到D盘
谢谢！

Answer 1

dim bsb,cpu,disk

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
Set colItems = objWMIService.ExecQuery( _
"SELECT * FROM Win32_BaseBoard",,48)
For Each objItem in colItems
bsb = "BaseBoard SerialNumber: " & objItem.SerialNumber & vbCrlf & bsb
Next

Set colItems = objWMIService.ExecQuery( _
"SELECT * FROM Win32_Processor",,48)
For Each objItem in colItems
cpu = "CPU ProcessorId: " & objItem.ProcessorId & vbCrlf & cpu
Next

Set colItems = objWMIService.ExecQuery( _
"SELECT * FROM Win32_DiskDrive",,48)
For Each objItem in colItems
disk = "DiskDrive SerialNumber: " & objItem.SerialNumber & vbCrlf & disk
Next

dim fso, f
set fso = CreateObject("Scripting.FileSystemObject")
set f = fso.CreateTextFile("D:\test.txt", true) '第二个参数表示目标文件存在时是否覆盖
f.Write(bsb)
f.Write(cpu)
f.Write(disk)
f.Close()
set f = nothing
set fso = nothing
MsgBox "已完成！"

复制到文本，另存为，右下角编码选择ANSI,类型选择所有，文件名：HWinfo.vbs

追问

非常感谢