Question

vb 如何自动用系统默认的浏览器打开指定网页，类似于hao123.com 的桌面版

vb 如何自动用系统默认的浏览器打开指定网页，类似于hao123.com 的桌面版，单击图标后什么也不提示，直接用系统默认的浏览器去打开设置好的网址地址。

如果有工程源代码，修改后网站编译就能用，那是最好的啦。如果有的希望分享一下，yangjun5008@qq.com,先谢啦

Answer 1

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

'常用窗口显示控制枚举类型
Public Enum eSEShowWinStyle
SEWinHide = SW_HIDE
SEWinNormal = SW_SHOWNORMAL
SEWinShow = SW_SHOW
SEWinMax = SW_MAXIMIZE
SEWinMinNotActive = SW_SHOWMINNOACTIVE
SEWinMinActive = SW_SHOWMINIMIZED
SEWinRestore = SW_RESTORE
End Enum

Public Function SEShellRun(sFileOrURL As String, _
Optional ByVal bWithParam As Boolean = False, _
Optional ByVal winShowStyle As eSEShowWinStyle = SEWinNormal) As Boolean
'执行一个程序、打开一个文档或打开一个URL
'若bWithParam=true，则将 sFileOrURL 的第一个空格前看做程序的文件名， _
'之后看作参数；否则都看作程序文件名，参数为空
'winShowStyle 表示窗口显示状态（最大化、最小化、隐藏等）

Dim strFileOrExe As String, strParam As String
strFileOrExe = sFileOrURL
strParam = vbNullString

If bWithParam Then
'分出 sFileOrURL 中的程序文件名和参数
Dim intSpacePos As Integer
intSpacePos = InStr(sFileOrURL, " ")
If intSpacePos Then
strFileOrExe = Left$(sFileOrURL, intSpacePos - 1)
strParam = Mid$(sFileOrURL, intSpacePos + 1)
End If
End If
'调用 ShellExecute 函数
SEShellRun = ShellExecute(0&, "open", strFileOrExe, _
strParam, vbNullString, CLng(winShowStyle)) > 32
End Function

SEShellRun这个函数使用起来很方便的，用法举例：
运行程序 SEShellRun "C:\Windows\System32\mspaint.exe"
打开文件夹 SEShellRun "C:\Windows"
自动启动关联程序打开文档 SEShellRun "E:\my\abc.txt"
打开网页：SEShellRun "http://www.163.com"
发送邮件：SEShellRun "mailto:abc@def.com"

你问的就是打开网页的功能那是它其中的一个功能而已。

这段代码取自新书“老兵新传：Visual Basic核心编程及通用模块开发”（清华大学出版社），书中像类似这种方便调用、增强VB功能的代码还有很多很多，感兴趣就看看
你不是需要工程源代码吗？那里可能正有你需要的，不是修改后就能用，而是不需修改直接调用！