Question

易语言记事本怎么写自定义背景 （用图片做背景那断怎么写）求大神

Answer 1

.版本 2

.DLL命令 CreatePatternBrush, 整数型, "gdi32", "CreatePatternBrush"

    .参数 hBitmap, 整数型

.DLL命令 GetWindowLong, 整数型, "user32", "GetWindowLongA"

    .参数 hwnd, 整数型

    .参数 nIndex, 整数型

.DLL命令 SetWindowLong, 整数型, "user32", "SetWindowLongA"

    .参数 hwnd, 整数型

    .参数 nIndex, 整数型

    .参数 dwNewLong, 整数型

.DLL命令 CallWindowProcA, 整数型, , "CallWindowProcA"

    .参数 lproc, 整数型

    .参数 hwnd, 整数型

    .参数 umsg, 整数型

    .参数 wparam, 整数型

    .参数 lparam, 整数型

.DLL命令 DeleteObject, 整数型, "gdi32", "DeleteObject"

    .参数 hObject, 整数型

.DLL命令 SetBkMode, 整数型, "gdi32", "SetBkMode"

    .参数 hdc, 整数型

    .参数 nBkMode, 整数型

此行不复制=============================================================

.版本 2

.常量 GWL_WNDPROC, "-4"

.常量 WM_CTLCOLOREDIT, "307"

.常量 TRANSPARENT, "1"

此行不复制==========================================================

.版本 2

.程序集 窗口程序集1

.程序集变量 lpOldProc, 整数型

.程序集变量 hBlackBrush, 整数型

.子程序 __启动窗口_创建完毕

.局部变量 图片, 对象

图片.创建图片对象 (读入文件 (取运行目录 () ＋ “\1.jpg”))

hBlackBrush ＝ CreatePatternBrush (图片.读数值属性 (“handle”, ))

lpOldProc ＝ GetWindowLong (取窗口句柄 (), #GWL_WNDPROC)

SetWindowLong (取窗口句柄 (), #GWL_WNDPROC, 到数值 (&WndProc))

.子程序 WndProc, 整数型

.参数 hwnd, 整数型

.参数 umsg, 整数型

.参数 wparam, 整数型

.参数 lparam, 整数型

.如果真 (umsg ＝ #WM_CTLCOLOREDIT)

    SetBkMode (wparam, #TRANSPARENT)

    返回 (hBlackBrush)

.如果真结束

返回 (CallWindowProcA (lpOldProc, hwnd, umsg, wparam, lparam))

.子程序 __启动窗口_可否被关闭, 逻辑型

.如果真 (hBlackBrush ＞ 0)

    DeleteObject (hBlackBrush)

.如果真结束

.子程序 _编辑框1_内容被改变

编辑框1.重画 ()

.子程序 _编辑框1_滚轮被滚动, 逻辑型

.参数 滚动距离, 整数型

.参数 功能键状态, 整数型

编辑框1.重画 ()

Answer 2

编辑框不支持背景图片，要用背景图片的话，可以到易语言官方论坛上搜索组件背景透明的相关帖子。

追问

可以先用图片框载入一张图做为背景 ，然后编辑框调成背景色？

追答

是用非常手段让编辑框的背景透明，显示出你用作背景的图片。